*label ch5_dates
*page_break
I find myself having a couple of days off. It's quite a rare instance and I'm unsure what to do.
*if not(ch5_met_someone)
    Perhaps I should try to locate…

*label ch5_met_someone
*if ch5_met_someone
    There's still time to meet someone else. Is there someone else I would like to meet?

*choice
    *hide_reuse #Marcus.
        *goto ch5_date_marcus
    *hide_reuse #Tinsae.
        *goto ch5_date_tinsae
    *hide_reuse #Niall.
        *goto ch5_date_niall
    *hide_reuse #Camilla.
        *goto ch5_date_camilla
    *hide_reuse #Quinn.
        *goto ch5_date_quinn
    #No one.
        *goto_scene chapter5_optio


*label ch5_date_marcus
*label ch5_marcus
Niall told me that Marcus is most likely in a library nearby.

The library is lit like an outdoor space due to multiple windows letting in the midday sun. There are tables littered all across the vast hall. There are women and men in fine tunics and some men in their togas, some reading out loud, some quietly. I wonder how they can even focus on their texts in such a noisy environment. There's the smell of dust and leather, it mixes in with the sickly-sweet perfumes of the Romans.

A part of me still wonders why I'm even here.

Ah. There he is. The man I was looking for: Marcus sits in front of a large scroll. His usually tamed hair is slightly disheveled. He seems to be reading, but for some reason he also squints at the scroll in anger. He reminds me of an annoyed little vole.

He rakes his hand through his hair, almost tearing strands with it.

"What are you doing?" I ask and he jumps on his seat.

"[i]Merda[/i]!" Then, when he realizes it's me, he shakes his head. "It's you." The tone of his voice accompanied with the look on his face tell me that he's both annoyed and unimpressed by my presence.

Rude.

*if samhain_marcus
    Then, a small grin appears on his face, indicating that nothing good will come out of his mouth. "What are you doing here, my dear future spouse?"
    
    "What?"
    
    "The nuts, remember?"
    
    Those stupid nuts.
    
    *fake_choice
        #I sigh. Here we go again.
            He looks like a lynx that swallowed a pygmy owl. I brace myself for his idiocy.
        #"I am not your spouse and I will never be."
            He grimaces. "I'm devastated to hear that."
            
            I squint my eyes at him. He's joking. He's always joking. And it's never funny.
            
            The grimace soon transforms into a self-content smirk. It makes me want to smack him. Then, like a hawk, he turns his gaze back to me.
        #A feeling of terror creeps into my spine. What if the gods are right?
            I look at him. Why would the gods torment me with this thought? Would they actually…
            
            No.
        #Ignore him.
            I sigh and look away. Usually, he doesn't feel like continuing if I don't interact with him.
            
            This time, however, he looks more resilient than usual. He's watching me like a self-content lynx.
            
    "You're thinking about it, aren't you? Our future together?"
            
    "No."
            
    "Would you like me to buy you a villa? We could retire and start growing grapes. Our children would be running—"
            
    "Children?"
            
    "We can always adopt. Don't you worry your pretty little head about it. Tinsae could—"
                
    "That's not the part that I—"
            
    "Oh? So you don't mind children? That's great. I don't mind them, either. Some can be snotty little brats, sure, but—"
    
    *fake_choice
        #"Shut up."
            He pouts. "But—"
            
            "No. Shut up."
            
            He sighs. "Fine." He looks away, as if hurt.
        #"Are you serious?"
            "Why wouldn't I be?"
            
            "You're…" He must be kidding me. It's one of his ruses.
            
            "I'm?" He smiles, confirming my suspicion. When I don't answer, he sighs. "Oh, fine. You still need some softening up."
            
            "No—"
            
            "I can wait." He sighs.
        #"Of course I want to get married to you. And have so many children."
            I smile at him, both of us knowing fully well that I would rather die.
            
            "What a relief! It's so important for partners to have shared future plans. I can be flexible but I really want those grapes."
            
            "I could feed them to you while you lie on your back, basking in the sun."
            
            He nods. "Oh, yes." Then, the joking tone starts to fade from his features. Instead, he starts looking awfully serious. He looks me in the eyes and says: "I can see it."
            
            I frown. "I'm not serious."
            
            He pouts.
            
            Before he can start, I say: "Yes, yes. Your heart. Can we now change the subject?" He won this round.
            
            He smiles in content.
    "You didn't answer my question. Why did you come here?"
    
*if not(samhain_marcus)
    "What are you doing here?" He asks.

*fake_choice
    #"Watching you read like a little vole."
        He squints his eyes. 
        
        "Uh-huh. Just like that."
        
        A little scoff leaves his thin lips. "So, you've been spying on me?" He raises his brow, preparing for a counterattack. "Got a good look of my stunning jawline?"
        
        "You tightened it so forcefully that I couldn't possibly miss it," I retort and look at the scroll. "Small text?"
        
        He sighs. "I'll manage."
    #"I just wanted to find something to read." I shrug.
        *set manipulative +1
        It's a lie, I came in to look for him. Even if I'm not sure why, it's him that I'm here for. Probably I just want to ruin his day.
        
        He squints his eyes before shaking his head. "Then begone and let me read in peace."
        
        I'm not going anywhere.
    #"What's it to you?"
        *set rude +1
        He opens his mouth with a frown. "I suppose it's not. Begone, then." He turns his attention back to the text. 
    #Remain silent and shrug.
        I give him a little shrug. Why wouldn't I want to visit library, anyway? Sure, I came here to look for him but it's none of his business as to why.
        
        He sighs and turns his attention back to the text.
    
I peek at the text. It looks perfectly normal, even if it's on the smaller side.

"There's nothing wrong with that. How come you can't see?"

"Ugh." More than anything, he sounds defeated. He sighs again. "It is what it is."

*fake_choice
    #Remain silent and nod.
    #"It's what happens when you're an old fart."
        He purses his lips. "Yes. A 30 something old fart."
        
        "Well over 30," I remind him.
        
        He groans. "Are you here just to bully me?"
        
        I shrug and peer at the scroll. Perhaps I am.
    #"There there. It's normal in your age."
        He takes a deep breath, fully filing his lungs and exhaling before saying: "Yes, yes. Had your fun?"
        
        Fun? I frown at his words. Am I having fun with him?
        
        The resigned look on his face is replaced by a smirk. "Realizing you have feelings for me?"
        
        *fake_choice
            #"Yes. The feeling of hatred."
                He snorts. "A decent comeback. I'm proud of you."
                
                "Thank you so much."
            #"You wish."
                "Oh, but I do." He sighs, as if wistfully, and looks away. "That's what my heart yearns."
                
                "Shut up."
                
                "You started it. I was just reading peacefully before you arrived to insult me."
                
                "You started this when you killed everyone I hold dear."
                
                He flinches at my words. 
                
                Good. If that is what I need to use against him, I will. Besides, every single word I spoke was true. Now I've got a weapon against him and I'm not afraid to use it. The bastard.
                
                I peer at the scroll.
            #I blush and almost groan at myself because of it.
                *set blusher true
                Why do I always make it easy for him? 
                
                Once the heat reaches the tips of my ears, he wears a wide, and so infuriatingly smug smile.
                
                *fake_choice
                    #"As if I had feelings for the man who murdered everyone I hold dear."
                        The smile on his face dies as he looks away.
                        
                        Ha! I found the thing that will shut him up. If that is what I need to use against him, I will. Besides, every single word I spoke was true. Now I've got a weapon against him and I'm not afraid to use it. The bastard.
                        
                        I peer at the scroll.
                    #"Can you please not?"
                        The smug smile on his face softens, just a little. He nods. "Fine. Since you asked so nicely."
                        
                        That was surprisingly easy.
                        
                        I peer at the scroll.
                    #Ignore him with a pout on my face.
                        I'm so done with this man. A part of me wants to punch that smug smile out of his face.
                        
                        Why did I come here?
                        
                        "You're so cute. That little pout on your face, it's adorable."
                        
                        I bite my lip and squint my eyes.
                        
                        "Fine, I'll leave you alone. You, however, should do the same for me."
                        
                        Yes, yes. Anyway, what is that idiot reading about? I peer at the text.
                
    #"That's cute."
        I almost frown at the words that leave me. Where did that come from?
        
        He seems as perplexed by the thought. "Cute? That I can't see properly?"
        
        "Yes." I'm just teasing him, of course. He couldn't be cute. The way he tried to peer at the text, his nose almost smudging the scroll… it wasn't actually cute but it could've been cute, if the person was anyone else but him.
        
        Yes. That's what I meant.
        
        "That's a weird conception of cuteness."
        
        "Well, yes, anyway…" I peer at the scroll.
There are words like 'naked' and 'bosom'.
        
What is that?
    
*page_break
"What are you reading?" I ask.

"How are you that interested in what I do in my free time?"

I shrug.

He shakes his head. Then, he answers in a dry tone: "Sulpicia."

"Who's that?"

"She's a satirist."

"What does she write about?"

"Erotic musings on how much she loves her husband."

"I see." That explains the vocabulary.

*fake_choice
    #I'm silently judging him for reading erotic poems. In a public library, no less.
        Isn't that awkward? What if he gets… aroused? Is that his goal?
        
        He raises his brow at me. "What?"
        
        "Nothing."
        
        "I see you judging me. Is it because it's a collection of erotic poems?"
        
        "Well… I mean, this is quite a public space to be reading something like that."
        
        He sighs. "I'm not masturbating while reading, you moron."
        
        *fake_choice
            #"Hey, I'm not judging." I am.
                *set manipulative +1
                "You're not even believing your own words."
                
                No, I'm not. 
            #"I didn't say you were!" I was just thinking it.
                My shout provokes someone nearby to hush us. A man near our table looks at us with irritation painting the whole of his face. What is his problem? There are people shouting while reading, how is me shouting at this idiot any different?
                
                Marcus continues, all the while ignoring the stares: "You were thinking about it. Besides…" He glances at the irritated man. "You're going to anger the whole library if you keep shouting like that."
                
                "It was your fault for making things sound weird…"
                
                "I merely stated that I'm not in the middle of jacking it off."
                
                Why does he have to phrase it like that? Please. No.
                
                He shakes his head, as if being utterly disappointed in me. "I'm enjoying poetry all quietly and you're here accusing me of masturbation, of all things."
                
                I sigh. He won this round.
            #"I'm just saying... Couldn't you read things like this at home?"
                "Why?"
                
                "Well… you know. Shouldn't that be private?"
                
                "Look, I know this might surprise you but I'm not reading these because I want to be aroused."
                
                "Why, then?"
                
                "It's good poetry. Is that so difficult to understand?"
                
                I squint my eyes at him. Would he really do anything without ulterior motives? Would he really be here just because he enjoys poetry? I find it unlikely.
                
                When I don't answer, he scoffs: "Do you [i]want[/i] me to start jacking it off?"
                
                "What? No!"
                
                "It sure sounds like it." He shakes his head, as if disappointed in me.
                
                I sigh. He won this round.
            #"Now I'm just more sure that you were masturbating since you're denying it so forcefully."
                "If that is what you wish to imagine, me jacking it off, then by all means, you're welcome to think so."
                
                "I didn't—"
                
                "I didn't ask you to come here and share your fantasies about me and my masturbating ways but here we are." He shakes his head, as if disappointed in me.
                
                I sigh. He won this round.
    #"Erotic poems, huh?"
        He shrugs, clearly expecting me to ask. "It's interesting. You rarely have a woman's point of view on the matter in written form."
        
        "In Rome?"
        
        "Yes." 
        
        "Because you belittle your women and their writing?"
        
        He purses his lips. "No."
        
        "No?"
        
        "Let's not… This is a woman who writes and I'm not belittling her. I'm enjoying her work."
        
        "But usually in Rome—"
        
        "These are complicated issues."
        
        *fake_choice
            #"How is that complicated?" I challenge him.
                "It's awfully non-complicated for us Picts."
                
                "Yes, I'm aware." He sighs. "It's just what it is."
                
                "Spoken like a man who just doesn't want to do anything about it."
                
                "You Picts don't even write."
                
                "Yes. But we don't view the women as being inferior to men."
                
                He gestures the scroll. "What am I doing if not listening to a woman and not belittling her?"
                *if gender = "woman"
                    Then, he turns his attention to me with a raised brow. "And some other woman that I know of…"
                    
                    "Are you saying you don't belittle me? Are you serious?"
                    
                    "But not because of your gender."
                    
                    As if that's his big achievement in life.
                
                He sighs and before I can continue arguing, he says: "You know, I was having a relaxed day here with my poems and then you came."
                
                I nod. Good. I ruined his day. That's what I'm here for.
            #Let it be. I don't want to start a fight even if his reasoning is idiotic.
                I fall silent. They are not that complicated issues, though. He's an idiotic Roman and his peers are as idiotic for thinking that women are inferior to them. However, this is not the place to start a debate with him.
                
                "Thank the gods," he sighs.
                
                "What? I can continue if you want to."
                
                "No, please. I've had quite enough of your babbling. I was having a relaxed day here with my poems and then you came."
                
                I nod. Good. I ruined his day. That's what I'm here for.
            #Let it be. I don't care to talk about this stuff.
                I shrug. 
                
                "Thank the gods," he sighs.
                
                "What?" I can continue if he wants to.
                
                "No, nothing. Please don't take that as a challenge to speak anymore. I've had quite enough of your babbling. I was having a relaxed day here with my poems and then you came."
                
                I nod. Good. I ruined his day. That's what I'm here for.
    #I give him a nonchalant nod. I don't care what he reads.
        He waits for me to say something. When I don't, he says: "You don't care that I read erotic poems?"
        
        "Would you want me to?" It sure sounds like it.
        
        "Not necessarily. Just thought it would arouse some sort of reaction."
        
        I shrug.
        
        With a chuckle he adds: "Arouse, get it?"
        
        I just give him a dead stare.
        
        He purses his lips in disappointment. "Tough crowd."
    #I understand. I've read quite a few erotic poems. They can be quite tasteful.
        *set a_man_of_culture true
        I nod in understanding. Nothing wrong with that.
        
        He waits for me to say something else. Nearby people rustling their scrolls is the only thing we hear for a good while. When nothing happens, he asks: "That's it?"
        
        "What?"
        
        "Aren't you going to tease me?"
        
        "Would you want me to?"
        
        "Well, no. It's just… they're erotic poems."
        
        "I've read a few myself. They can be quite good."
        
        His face lightens up. "You have!" Then, as if trying to calm himself down, he adds in a more solemn tone: "Well, good. What have you read?"
        
        "A couple of Martial's dirtier poems."
        
        "You've read Martial!" 
        
        His shout provokes someone nearby to hush us. A man near our table looks at us with irritation painting the whole of his face. Marcus waves at him dismissively and continues to stare at me. He looks like he has so much to say that he doesn't know where to begin.
        
        Finally, he starts: "I will need to have your opinion on Martial's production. Domitian's reign influenced a lot of his writing in his first books and—"
        
        He continues to prattle about the politics during the production of the books. Then, he moves on to his patrons, how he would've been an amazing patron for him, how he would've bought him a villa or another, how—
        
        *fake_choice
            #Remain silent. My mind blanks.
                He talks and I don't even pretend to listen. I look into the distance with my mind blank.
                
                Finally, he seems to stop babbling. 
            #I keep nodding politely, even though the topic doesn't interest me that much.
                *set rude -1
                Even if I've read some of Martial, it's not like I want to hold a whole conversation about him. But, he's clearly passionate about the topic. Despite the fact that it's Marcus we're talking about, I still find it difficult to interrupt his talk.
                
                So, he keeps talking for a good while. I think my mind blanks for a moment or two. 
                
                Finally, he either realizes that his crowd isn't paying attention or he ran out of energy, and he stops talking.
                
                Thank the Twins.
            #"I'm not that interested in talking about Martial."
                *set rude +1
                *set marcus_rival +1
                A frown pervades his features as he gives me a pout. In short, he looks at me as if I shattered his heart. Quickly enough, he shakes his head and turns away. "Of course. I wouldn't expect a moron to appreciate the great Martial."
                
                Ha. At least I got to hurt him.
            #He's such a fan. It's almost endearing.
                *set marcus_friendship +1
                I almost smile at the way he keeps babbling away about the wit of Martial, how he often finds himself still smiling at his jokes, even after all the times he's read the poems by now. From time to time, he looks at me, to make sure that I'm listening. To reassure him, I give him a little nod back.
                
                I'm not sure why I even bother. There's something about a person being excited about one topic they're into. Even if it's him.
                
                I find myself smiling at him.
                
                Oh, no. No no no. 
                
                I'm [i]not[/i] smiling at the murderer of my father. I quickly look away with a deep frown on my face.
                
                He talks for a good while, and I find it difficult to not to look at him. I don't know why. Finally, he falls silent.
                
                Thank goodness.
                         
*page_break
Once again, he looks at the scroll. Then, he looks at me.

"Well?"

"What?"

"Are you just going to stand there?"

"I…" Now that he's asking, I'm not exactly sure what I was supposed to be doing here. Why am I here talking to him when I could be literally anywhere else? 

"Judging by the frown on your face, you're not sure either. You're wondering why you're here. Let me guess…"

"No."

"It's because you can't stay away from me."

I sigh.

"I knew it. I suppose I should feel happy about it, however, your presence has distracted me from my enjoyment. I can concentrate no longer. You've ruined my day."

I nod in satisfaction. Great.

"Now you'll have to accompany me to lunch."

I wrinkle my nose at the thought. "What? Why?"

"Why not? I'm hungry and you have nothing better to do. Besides, I doubt you've eaten your lunch yet."

"Yes, I do have better things to do. I—"

"It's an order, now come on."

*page_break
The forum is as busy ever. 

We pass by vendors trying to sell their wares towards the food stalls. Smells of burning flesh alongside with garlic, onion, cabbage fill my nostrils. The smells are strong; it's difficult to say if they make me hungry or want to gag.

It's a mix of both. I haven't eaten since breakfast. Marcus was right in that regard, at least. 

The smells grow stronger and stronger as we finally find the restaurant. It proves to be a small room open on the streets. There's a smiling man behind a masonry counter. He gives us an enthusiastic greeting and gestures at the wall behind him.

There are paintings on the wall depicting what food can be ordered: roasted cabbages, pickled eggs, bread, cheeses, sausages, olives, minced meat patties, skewers of meat, fish, sweets… The food seems to be stored in large containers made of clay.

"What do you want?" Marcus asks.

*fake_choice
    #"You to die."
        *set whatever_youre_having true
        He scoffs. "What would people think if I dropped dead on the street?"
        
        "I'm sure those who knew you would be happy."
        
        "Ha! Perhaps. I'm not ready to brighten up their day in such a way. I'm talking about food."
        
        I shrug. I'm not sure. I'm too hungry to decide.
        
        "I'll order something," he says and turns to the man behind the counter. He orders cabbages, pecorino, olives, and focaccia with thyme and rosemary.
        *if vegetarian
            He didn't order any meat. Because he knows that I don't eat it?
            
            I almost scoff at the thought. As if he'd be that considerate.
    #"I'll have what you're having."
        *set whatever_youre_having true
        The place is too busy and loud for me to begin to decide anything. I'm hungry, just give me anything.
        
        He smiles to himself but doesn't say anything else. Instead, he orders cabbages, pecorino, olives, and focaccia with thyme and rosemary.
        *if vegetarian
            He didn't order any meat. Because he knows that I don't eat it?
            
            I almost scoff at the thought. As if he'd be that considerate.
    #"A whole platter of sausages and meat patties and a bunch of those skewers."
        *set meat_please true
        *if vegetarian
            *set vegetarian false
            He turns to me a with a raised brow. "Weren't you a vegetarian?"
            
            "Are you deciding what I can and cannot eat?" I don't know where the urge to eat meat came from but I don't have the willpower to deny it. I just need meat. And I don't need him to judge me for it.
            
            "No, no. I'll order the meat." He gives me another quick glance. "You're going to have an aching tummy, though."
            
            I squint my eyes.
        
        "Are you sure you don't want any cabbage? It would be healthier than a—"
        
        "I want meat."
        
        "Alright, alright." He chuckles and orders the meat.
    #"I'll have something sweet."
        *set sweet_tooth true
        *if still_broken
            I know I shouldn't. I know I said to Quinn that I don't eat sweets. But I need it.
            
            "Why are you looking so serious about this?"
            
            "I want cookies."
        *comment tähän muutos niin että ottaa vaan jos otti quinnilta keksiä
        He lets out a laugh. "It's a lunch hour. You can't just eat sweets."
        
        "Who says I can't?" I frown at him. Is he trying to stand between me and my sweets?
        
        "Hey hey, I'm not saying you can't." He raises his hands in surrender and turns to order me honey ricotta cookies, a piece of honey cake, and some dried fruit.
        
        I nod in content and take the spoil with a smile. I take a bite of the honey cake and let out a little hum.
        
        Marcus snickers to himself. "Careful, your energy levels will—"
        
        I shake my head. Don't talk to me. I'm eating.
        
        "Fine, fine. Eat your little heart out."

*page_break
A cart approaches the restaurant, clanking its iron wheels loudly against the stone pavement. Once it stops, a man inside the cart yells: 

"Give me the usual!"

Quickly the vendor gathers his food, an assortment of meats, and hurries to give it to the Cart Man. The Cart Man throws some money on the ground, and quickly continues his journey.

The vendor sighs and starts collecting the coins.

*fake_choice
    #Go and help him.
        *set ruthless -1
        What a rude man! Nothing I shouldn't expect from the Romans. 
        
        "Please, let me help," I say and start gathering the little coins with him. The Cart Man paid with little copper coins and many of them rolled far away from the vendor. Absolutely vile behavior.
        
        Soon enough, Marcus appears next to me to collect the last of the coins. He gives me a little lopsided smile.
        
        "Aren't you helpful."
        
        "Thank you so much, both of you," the man bows us with his hands now filled with quadrans.
        
        I give him a nod and a little smile. 
    #I shrug at the scene. Stupid, rude Romans.
        Nothing I shouldn't expect from the Romans. Of course they treat each other like dirt.
        
        Then, Marcus sighs and starts collecting the coins with the vendor. The man looks at him with a grateful smile. Once they are done, he turns to me:
        
        "Are you coming?" 
    #Ignore what happened.
        *set ruthless +1
        Soon enough, Marcus sighs and starts collecting the coins with the vendor. The man looks at him with a grateful smile. Once they are done, he turns to me:
        
        "Are you coming?"

*page_break
With the food in our hands, Marcus leads me to a public garden. The plants have all but died, there's only a few late-bloomers who will most likely meet their demise in a couple of days.

So, we start eating in uncomfortable silence. However, it's difficult to say if the silence is truly uncomfortable for him, or just me.

He just chews his food. The sound is loud. It's irritating. 

Ugh. I take a bite of a
*if sweet_tooth
    honey cookie
*if meat_please
    sausage
*if whatever_youre_having
    piece of cheese
with a slight frown on my face.

"Was the food that bad?" Marcus asks.

"No." It's your presence that irks me. He shrugs and continues eating, evidently not minding the silence.

It's weird. I would've thought that he'd want to talk about what happened.

"Aren't you going to ask?" I ask. Not sure why. Father always said that one should try to clear the air after disputes.
*if marcus_killer_samhain
    I suppose a murder attempt can be counted as a dispute.
    
However, him and I are going to have a life-long dispute that will never be resolved. So, does it matter that we had one on top of that?

He looks at me, evidently not understanding what's the thing he should be asking about. 

Ugh. "Don't you think we should talk about what happened?"

"What happened when?" Now he's just acting oblivious.

"During Samhain."

He looks at me, purses his lips, and says: "No. I don't think so." He inspects the cabbage in his hands as if it's the most important thing at the moment.

*if marcus_killer_samhain
    "But I almost killed you."
    
    "Well, you didn't."
    
    How is he so calm about it? Just a casual murder attempt, is that it?
    
    He raises his brow at me. "Don't try to kill me now, alright? I'm eating."
    
    "This isn't funny? I tried to—"
    
    "Yes yes. I was there. I know what happened. However, you're still here and, unfortunately for you, I'm also still here." He takes another showy bite of his cabbage. "And I'm eating." 
    
*if not(marcus_killer_samhain)
    "But—"
    
    "Look. Can't you see that I'm trying to eat? First you invade my poetry-sessions, then this." He takes a deep sigh. "You're a menace."

I fall silent. He doesn't want to talk about it. I suppose it's fine. I'm not in the mood, either. So, silence takes over us once more.

*page_break
Finally, he sighs and turns to look at me. However, it seems that he's unable to look at me. His gaze darts all over the garden. Finally, he says: "I'm sorry for not realizing sooner that you need another place to bathe. That was my fault."

*fake_choice
    #"My form of revenge is to smell so bad you can't be near me."
        He gives me an exaggerated nod. "Well! I didn't want to say anything but you nearly did smell so bad." He leans closer to me. "Yeah, the stink still lingers."
        
        *fake_choice
            #"Don't you start sniffing me like a dog."
                "If I were a dog, I would smell you from miles away. I used to smell you from miles away, though, even with my regular human nose."
                
                "Hey!"
                
                "Yes. It's a wonder how you managed to smell so bad that I could tell you apart from other sweat-smelling soldier."
                
                I glare at him.
                
                "Well, not anymore. Thankfully you seemed to be able to wash some of it off before the Optio came in."
                
                I stifle to urge to roll my eyes. "Yes, that's the most important part of that ordeal."
                
                "Indeed." He smirks and continues eating.
            #Punch him on his arm and don't hold back.
                I punch him. He deserves it. The punch lands perfectly.
                
                "What in the hells!" He rubs his arm with cabbage sticking out of his mouth. "For fuck's sake, now you're assaulting me?"
                
                "It's your fault for provoking me!"
                
                "That's what abusers say to their battered spouses."
                
                "What, no—"
                
                "Mm-hm." He gives me a scolding look.
            #Lightly punch him on his arm.
                A part of me doesn't want to hurt him too seriously, for whatever reason. I should want to punch him so hard that he'd find himself back from Rome.
                
                So, I lightly tap his arm with my fist. It's pathetic, it lacks any will behind it, and I don't know why I even bothered.
                
                He looks at his arm. "Are you calling that a punch?"
                
                I frown. "Do you want another one?"
                
                "No, no. Thank you very much." Then, he looks at me with a devious grin. "Can't hurt me, huh? You already love—"
                
                "Alright, that's it—" I roll up my sleeve and prepare myself for a more violent punch.
                
                "I jest!" He laughs.
    #"I won't forgive you." I'm serious. It's his fault that I was almost killed. Again.
        He sighs. "You can put that on the list."
        
        "The list? Of your murder attempts at me and my family? You're joking about this?"
        
        "Yes." He shakes his head. "That's my defense mechanism."
        
        What a shitty defense mechanism.
    #"It's fine."
        I could hold it against him. However, I won't.
        
        He raises his brow at me. "Really? When did you turn into such a forgiving person?"
        
        "What do you know about what kind of a person I am?"
        
        "Hm? Are you seriously asking me that?"
        
        Well, yes. I did come here to have my revenge. I shake my head. "Let's just drop this."
        
        "Fine by me."
    #Remain silent.
        He looks at me with a mockingly wistful look on his face. "That's one of your good graces."
        
        "What?"
        
        "Your silence. I can just imagine your reaction to everything I say. Now, for example, you are so humbled by my thoughtfulness that you're stunned into silence."
        
        "Uh-huh."
        
        He nods, looking quite pleased with himself.

*page_break
*if floyd_nooo
    "Aren't you sorry for what happened to Floyd?"
    
    "Sad? Because he chose to protect you?"
    
    "Because you ordered him to be tortured."
    
    "Tortured?" He sighs. "You can't expect to act like a fool and not receive any punishment for it. This time it was him who paid the price."
    
    "But wasn't there any other form of punishment that—"
    
    "Hey," he looks at me, making sure I take in his words. "It was either him or you. I made my choice."
    
    I bite my lip. It's true. He did. He did save me. Again. 
    
    *fake_choice
        #"Thank you."
            He raises his brow. He waits for something.
            
            "No insults? Just a thank you?"
            
            "I can insult you if you want to."
            
            "No, no, that won't be necessary." A self-satisfied grin appears on his face as he looks down on his cabbage.
        #"Why do you keep saving me?"
            "Why?" He looks down and sighs. "Because you're an idiot who'd get killed without me."
            
            Ugh. What else did I expect than insults?
            
            However, why is he keeping the so called idiot alive, if he really thinks that? Am I his plaything? Is that what this is?
            
            He takes a bite of his cheese. "Why do you care, anyway? Isn't it enough that you're alive?"
            
            "Wouldn't you care?"
            
            He tilts his head and presses his thin lips together. "You've got a point."
            
            But, rather than telling me of his true motives, he falls silent.
        #Remain silent.
            I do wonder why. But I'm not sure how to ask. And if I want to hear the answer.
            
            So, I choose silence.
            
            He seems content with that, as he keeps chugging down his cabbage with a content look on his face.

*page_break
"How is your plan going?" Marcus asks.

"What plan?"

"To kill me."

I raise my brow at him.

"We both know you came here to kill me."

*if hatred = "manipulated"
    I quickly shake my head. "It's not that simple," I say before I can think any better. I'm not sure if he should know about it. About how the details are still foggy. About how I got here.
            
    "Hm? Do elaborate." I have his full attention now. His dark eyes peer at me with interest.
            
    *choice
        #Tell him.
            *set marcus_trust +2
            *goto ch5_marcus_truth
        #Don't tell him.
            I shrug. "It's just not."
            
            He purses his lips, fully knowing that I'm not telling him something. 
            
            Honestly, he should expect that at this point. I don't owe him anything. Least of all the truth.
            *goto ch5_marcus_scar
        #"None of you business."
            "Pfft. I'm just curious."
            
            "Still not going to tell you."
            
            "Suit yourself."
            *goto ch5_marcus_scar
            
*if hatred = "determined"
    I nod. "Yes."
    
    He cocks his head, a little grin tugging at his lips. "Who are you going to kill after me?"
    
    *fake_choice
        #"Your father. The Emperor. The General?"
            *set manipulative -1
            He raises his brows and starts chuckling. "All the way to the Emperor! That's the spirit." 
                        
            "I'm not sure about the order, though."
            
            "Oh? You're keeping your options open, that's good." Still chuckling to himself, he adds: "I love that you're so honest. That's one of your good graces."
            
            He looks more pleased than I thought he would. I'm not sure what I expected, though. This whole conversation is a whole another level of weirdness.
            
            "You're not sad about me planning on killing your father?"
            
            "Oh, no. The old geezer deserves it."
            
            Huh. Family problems.
            *if legate_secret
                Quinn did tell as much.       
                
            But how much of this are his true feelings? Why would he be speaking the truth to someone who's planning on killing him? 
            *goto ch5_marcus_scar
        #"No one. I've changed my mind." I'm lying.
            *set manipulative +1
            He cocks his head slightly before scoffing. "No one believes you. You're a terrible liar."
                        
            I shrug. I simply won't talk, it's easier to lie that way. Maybe he won't believe me now but I'm sure he will let his guards down sooner or later.
            *goto ch5_marcus_scar
        #"No one..." I think I've started to change my mind.
            *set hatred_doubter true
            Have I truly? Why? I'm here, I need to do it. I need to kill him.
            
            He looks at me, clearly making a judgment of whether I'm speaking the truth or not. I'm not sure myself. I don't know what to think.
            
            "I—"
            
            I want to say that I have clear plans. But why aren't they clear anymore? Why have they turned into a foggy mess? 
            
            He shakes his head while letting out a little chuckle. "I see."
            
            He doesn't elaborate on the comment, he just turns his attention back on his food.
        #Why don't I feel the same need to kill him as before? Why? 
            *set hatred_doubter true
            I frown at the thought as I look at him. I should want to kill him. That's what I'm here for. 
            
            He looks back at me, tilting his head, clearly trying to make sense of me. Can he see the turmoil that I feel?
            
            "I—"
            
            I want to say that I have clear plans. But why aren't they clear anymore? Why have they turned into a foggy mess? 
            
            He shakes his head while letting out a little chuckle. "I see."
            
            He doesn't elaborate on the comment, he just turns his attention back on his food.
    *goto ch5_marcus_scar

*label ch5_marcus_truth
*page_break
"I… don't remember how I got here." It feels wrong to tell him. He might use the information against me. However, something in me wants to share that information with him. Perhaps because I'm scared of the implications. Perhaps I want someone to know.

He peers into my eyes and nods. "I'm listening. What is the last thing you remember?"

"I remember bits and pieces. I remember Quinn telling me to leave."

I frown at the memory. Did ${q_he} tell me to leave? Wasn't it me who wanted to go?

Marcus wrinkles his nose at the sound of Quinn's name.

"Then there's… A vision of a dirt road. Of a forest. Of a ship."

Marcus furrows his brows. "That's it? And then you woke up here?"

"Well, yes."

Silence falls between us as Marcus falls deep in thought.
*page_break
*if marcus_voices
    He asks: "Have you heard the voice again? Do you think these things are connected?"
    
    I can't tell him that it was Quinn. Would he even believe me?
    
    "I haven't." I'm not sure if I'm convincing. That's all I will say at this point. 
    
    There's another prolonged silence. Finally, he sighs.
    
"Do you think it's got something to do with the trauma you experienced?"

"Perhaps." It would be an easy answer. And a believable one. But for some reason, my gut tells me it's not trauma that made me forget.

He nods. "Please tell me if these things continue. We will figure something out." His jaw is tightened as he looks at me. He almost looks concerned. Over my well-being?

Would he truly be worried about me? Or is he going to hold the information against me? It's difficult to say.

Whatever the case may be, he already knows. It's too late to back down. So, I give him a nod.
*goto ch5_marcus_scar

*label ch5_marcus_scar
*page_break
Silence falls between us once more. His eyes are closed and his chin lifted as he basks in the early winter sunshine. My gaze is caught by a scar on his cheek. The scar that my father left him with.

I can't help but smile when I look at it. 

"You're looking at it?" He asks.

I nod.

"Your father made it."

I nod. He will forever carry the reminder that my father was a mighty warrior. 

Marcus gives me lopsided smile. "I'm happy to inform you that it hurt like hell."

"Good." The thought does make me happy. 

We share a smile. It feels almost absurd but the smile on his face is genuine.

*choice
    #I absentmindedly touch my own set of scars on my cheek.
        *set scar true
        *goto ch5_marcus_mc_scar
    #He looks at my freckles.
        *set freckles true
        *goto ch5_marcus_freckles
    #He looks at my face.
        *goto ch5_marcus_stare
    #"I think I should go."
        "Oh. You're free to do so."
        
        I don't remember asking for his permission. So, I quickly salute him and leave. At least my stomach is full for the day.
        *set ch5_met_someone true
        *goto ch5_met_someone

*label ch5_marcus_stare
Is there something on my face? I almost start to scrub my skin, but halt my hand just in time. I don't want to appear self-conscious about this.

With his gaze lying on my face, he says: "You know, I've never told you this before but…"

"What?" It's nothing good. I just know it.

"You are adorable."

Oh, for— I knew he would be an ass!

*fake_choice
    #Still, I feel a little shy. And it's infuriating!
        Why does he look like he means it? Why do I feel self-conscious about his gaze?
        
        The grin on his face widens. "Oh, don't tell me that it makes you feel something."
        
        "Yes. It almost makes me want to punch you." Just to stop him from looking at me like that.
        
        "Bah!" He laughs.
    #"Thanks. You, too." I'm being sarcastic.
        Of course I'm being sarcastic. Would anyone seriously think that I'd call the murderer of my entire tribe adorable?
        
        "My heart melts. Your sweet words will lull me to sleep tonight."
        
        "I hope it will lull you into eternal sleep."
        
        "Bah!" He laughs.
    #"Thank you." I'm being polite and non-reactive.
        *set rude -1
        "You are quite welcome."
    #Ignore him.
        He gives me a small smile. "Silence means that you agree with me."
        
        I shrug. Hardly.
        
        "Yes, it does. I don't make the rules."
        
        It sounds like he does.
        
        "It's decided, you're adorable." He seems content with himself.
        
*goto ch5_marcus_feeding

*label ch5_marcus_freckles
With his gaze lying on my face, he says: "You know, I've never told you this before but…"

"What?" It's nothing good. I just know it.

"Your freckles are just adorable." He leans towards my face, as if seeing them clearly for the first time. Surely, he's seen them before. He's just messing with me.

*fake_choice
    #I can't help but feel a little awkward when he's looking at me like that.
        Like what? 
        
        Like he's… seeing me for the first time. The way his dark eyes inspect every line of my face. Every imperfection.
        
        To make fun of me further? That must be his goal.
        
        He grins and asks in a low voice: "Are you feeling shy?"
        
        "No! I'm not."
        
        He scoffs and lets out a little chuckle. "You're a terrible liar."
        
        I exhale a breath I didn't realize I'd been holding in. Stupid Marcus.
        
        "Honestly, though." He gestures at my face. "Adorable."
    #"Adorable? Are you serious?"
        *comment
        "What? I can't call you adorable?"
        
        "No, not really."
        
        "Pfft. I can call you a cute little barbarian, too, if I want to."
        
        "No."
        
        He hums in content and takes a piece of cheese in his mouth.
    #"Thank you." I'm being polite and non-reactive.
        *set rude -1
        "You are quite welcome."
    #Remain silent and ignore him.
        He gives me a small smile. "Silence means that you agree with me."
        
        I shrug. Hardly.
        
        "Yes, it does. I don't make the rules."
        
        It sounds like he does.
        
        "It's decided, you're adorable." He seems content with himself.
*goto ch5_marcus_feeding

*label ch5_marcus_mc_scar
"Where did you get your scar?" He looks at the three scars on my cheek.

"A bear attack."

He raises his brow at me, clearly impressed. "Really? Tell me what happened."

"A mother bear was protecting her cubs. The wrong place, the wrong time."

"How did you survive?"

"I…" I lied on the ground and played dead. Is that what I want to tell him?

*fake_choice
    #Embellish the truth to make me appear more heroic.
        *set manipulative +1
        "I punched the bear in the face."
        
        Both of his brows are raised when he looks at me. "What? You punched a bear?"
        
        "Yes. Their noses are their weakest spot." Father always told me to punch and kick the bears in their faces. Then, he laughed and said that in reality I should play dead and pray to the Twins.
        
        Marcus remains silent for a while, weighing my words, inspecting my scar in thought. Then, he says: "Well, then. Remind me not to piss you off."
        
        Ha! He believed it. 
    #Tell the truth.
        *set manipulative -2
        "I, uh. Played dead and she left eventually."
        
        "Pfft. Should've known."
        
        "What did you expect? That I wrestled the bear? I wouldn't be here, if that was the case."
        
        "Indeed. I suppose it's a good thing."
        
        He supposes? Ugh.
    #"I'd rather not tell."
        "So it's an embarrassing story."
        
        "No, I just—"
        
        "Did you just play dead and pray to your gods?"
        
        "Well, no—"
        
        "You did that."
        
        I sigh. I did. 
        
        He smiles in content.
*goto ch5_marcus_feeding

*label ch5_marcus_feeding
*page_break
He looks at the uneaten
*if sweet_tooth
    cake
*if meat_please
    sausage
*if whatever_youre_having
    piece of cabbage
in my hand. "Aren't you going to eat?"

He takes the food before I can react and gives me a wolfish grin. "Let me feed you."

"Huh?"

"Uh-huh. Open your mouth. Say 'aah'." He mimics the act, as if talking to a toddler.

*choice
    #I open my mouth and say: "Aah."
        *goto ch5_marcus_aah
    #"No."
        I purse my lips into a thin line. I'm not going to let him feed me.
        
        "Pretty please?" 
        
        "What? NO."
        
        He pouts his lips in disappointment and pops the
        *if sweet_tooth
            cake
        *if meat_please
            sausage
        *if whatever_youre_having
            piece of cabbage
        into his own mouth.
        
        "That was mine!"
        
        "You can scoop it out of my mouth if you want to." He speaks with his mouth still full.
        
        What an idiot.
        *goto ch5_marcus_goodbye
    #Look at him as if he's lost his mind.
        "Are you serious?"
        
        "Where is your sense of humor?"
        
        "Gone with your sense of wit, it seems."
        
        "Ha! Indeed."
        *goto ch5_marcus_goodbye
        
*label ch5_marcus_aah
Maybe I'm just joking. Maybe I wanted to see if he'd actually feed me. Whatever the reason might be, my mouth is now wide open, waiting for him to make the next move.
        
His eyes glint in delight. "Didn't think you'd actually—"
        
I frown and start closing my mouth.
        
"No no! Keep it open!" He shoves the piece of
*if sweet_tooth
    cake
*if meat_please
    sausage
*if whatever_youre_having
    cabbage
into my mouth.
        
Every protest I might have had is muffled by the mouthful of 
*if sweet_tooth
    cake. It's good, though.  
*if meat_please
    sausage. It's good, though. Is that pork? Romans love their pork, it must be it. It's seasoned well.
*if whatever_youre_having
    piece of cabbage. It's good, though. It's seasoned well and burned just around the edges.
        
Quite good.
        
It takes a moment to realize that Marcus's gaze is glued onto me. He's holding another piece of food in his hand. 'Another one?' he asks without words.

I open my mouth again. This time he takes care to put the food in my mouth gently. His touch brushes my lower lip, immediately sending a jolt of shudder across my body.

My eyes widen at the sensation and I swallow
*if sweet_tooth
    the piece of cake
*if meat_please
    the piece of sausage
*if whatever_youre_having
    the piece of cabbage
so quickly that I start coughing.

Marcus frowns. "Oh, great. You and Niall would make a great pair." He starts smacking my back.

Once I stop coughing, Marcus has turned his attention back to his own food.

Good. That was weird. That won't ever happen again.
*page_break
*label ch5_marcus_goodbye
Finally, there's no more food. I start standing up, ready to flee from him. I don't know why I was here, anyway.

*if ch5_no_flogging
    "Leaving already?"
    
    "Uh-huh."
    
    He waves me goodbye. I salute and leave.

*if not(ch5_no_flogging)
    "Did you check on Floyd?" Marcus asks.

    *if ch5_floyd_see
        "Yes."
    
        "Did he tell you that Caesar joke?"
    
        I shake my head. "Unfortunately, he did."
    
        Marcus shakes his head, too. "Atrocious."
    
        We share a little smile aimed at Floyd. Then, I salute him and leave.
    *if not(ch5_floyd_see)
        I shake my head.
    
        "You missed a joke of the century."
    
        "I see." Something tells me I didn't miss that much. I salute him and leave.

*page_break
*set ch5_met_someone true
*goto ch5_met_someone

*label ch5_date_tinsae
I asked around and Camilla gave me directions to where Tinsae should be at the moment. It's her workplaces, she said. But the directions lead me further away from her shop.

As I make way away from the Forum, I take a little short cut through a narrow street. The graffiti on the walls are more prominent, there are the usual penises, a few scribbles about how this or that person 'was here'. Nothing unusual. The smell of piss is stronger than on the main street. That's to be expected, too. 

The early winter rays of sunshine don't reach my skin, it's blocked by the tall buildings.

Then, a voice alerts me. I'm always ready for a pick pocket, or a robber. However, this is not what I expected:

It's a scream of a baby. It's a clear scream of horror and panic. The shriek wrenches my heart. I quickly follow the voice, my step is quick.

It doesn't take long to locate the baby: they lie on the ground wrapped in a blanket. They scream for their parents to come and pick them up. The air is cold, too cold for a baby to be lying on their own in exposure.

*fake_choice
    #Pick the baby up.
        *set ruthless -1
        Without hesitation, I pick the little bundle up from the ground. They weigh almost nothing, a clear sign of a newborn. Worry and fear take over me as I whisper to them: "What are you doing here?"
        
        The baby answers in a little shriek of protest but, thankfully, they soon relax under my touch, thankful that they are not alone anymore. They're wrapped in a cotton blanket; at least the person who left them was considerate enough to think their body temperature. 
        
        Not to the point of not leaving them here where anyone with bad intentions could find them, mind you.
        
        My touch is a little unsure but I remember enough from the time when the twins were little. My job was to watch them during the time between my studies.
        
        *if empathetic_child
            The baby remind me of the little bunny that died of hunger, the one I couldn't save. 
        They look at me with their big, round eyes, probably unable to even make sense of my features, to see who took them into their arms. They'll just have to trust that I'm a good person. 
        
        A thought pops into my mind: What if I didn't take this shortcut? What if they would've—
            
        No. I quickly shake my head. No. It's better not to think about it. I'm here now.
                        
        As I'm starting to weigh in my options, a pleasant voice calls to me: 
        *if tinsae_true_name
            "${name},
        *if not(tinsae_true_name)
            "Hati,
        who is your little friend?" 
        
        Tinsae.
        
        Her pure white dress sways in the wind with her freely flowing curly black hair. She gives me a smile that soothes my worried mind before looking at the baby in my arms. A shadow crosses her face but it doesn't linger, it's gone as quickly as it came.
        
        "Hello there, little fellow. Aren't you a small one," she coos at the baby, gently running her finger on their chubby cheek.
        
        "I found them like this. I don't know who could—"
        
        "Shh. They are in safe hands now. You did well." Another smile, another surge of relief. "Would you be willing to give me the baby?"
        
        With careful movements I do as I'm asked: I give her the baby. Her touch is gentle but firm: this isn't the first time she's held one.
    #I take off to find someone who lost their baby.
        "Wait here, I'll be right back."
        
        The baby responds by screaming a little louder. 'Don't leave,' they would probably say if they were yet able to speak. 
        
        "I'm coming back, I promise," I say, despite knowing that a baby their age won't probably understand my words at all.
        
        I leave and start searching for… anyone, really.
        
        Then, a familiar face appears, making me sigh in relief.
        
        Tinsae.
        
        Her pure white dress sways in the wind with her freely flowing curly black hair. She gives me a worried smile. 
        
        "Is there a baby somewhere?" She asks.
        
        "I was just trying to find help."
        
        "Why didn't you take them with you?" She gives me a concerned gaze before starting to walk towards the hysterical crying.
        
        I bite my lip. I suppose I could have.
        
        Soon enough, we arrive back to the baby. Tinsae smiles at them. "Hello there, little fellow. Aren't you a small one," she coos at the baby as she gently, and without hesitation, picks the baby up into her embrace. She sways the baby and starts humming to calm them down. Soon enough, the baby stops crying.
        
        I start explaining the situation: "I found them like this. I—"
        
        "It's a good thing you did." She keeps lulling the baby.
    #Umm. What should I do?
        A surge of panic tries to take over me as the baby screams even louder. Shit. Did someone forget their baby here? I peek over my shoulder, secretly hoping someone would jog to me and thank me for keeping a watch over their lost baby. 
        
        However, the thought is absurd: Who would lose a baby in a piss-filled alley? This was no accident.
        
        It's most likely that they are abandoned, left to die in the cold.
        
        Another booming shriek from deep beneath the baby's gut alerts everyone in the proximity, and even farther than that. Two Romans with a hurried step take a quick look at the scene but instead of coming to check if something is wrong, they quickly keep walking.
        
        "Hey!" I shout after them but they don't look back.
        
        Well… There's nothing else to do but to pick them up. The back of the neck is something to keep a hold of, that's the most important thing. The back of the neck, the back of the neck—
        
        It becomes my mantra as I gather my will and summon the memories of taking care of the twins when they were little. The baby shrieks loudly, urging me to hurry up. Then, a voice calls to us: "Oh, don't cry little one."
        
        Tinsae.
        
        Her pure white dress sways in the wind with her freely flowing curly black hair. She gives me a smile that soothes my worried mind before looking at the baby on the ground. A shadow crosses her face but it doesn't linger, it's gone as quickly as it came.
        
        "Hello there, little fellow. Aren't you a small one," she coos at the baby as she gently, and without hesitation, picks the baby up into her embrace. She sways the baby and starts humming to calm them down. Soon enough, the baby stops crying.
        
        I start explaining the situation: "I found them like this. I—"
        
        "It's a good thing you did." She keeps lulling the baby as she raises her gaze to me. Relief paints her face.
        
The baby starts to seek a source of milk, their target is Tinsae's right breast. Tinsae merely shakes her head with a dribble of sorrow tainting her features: 
        
"My child, I'm so sorry. You will find no milk here." Her words do nothing to stop the baby from trying. Tinsae looks at me with a sad smile: "I think we should leave. The baby is hungry."
        
I nod and start following her lead.

*page_break
Tinsae leads me off the alley to a busy street. She calms the baby as they get scared by a loud cart passing by, and continues to lead us into a

When she opens the door, a wall of shrieking, hushing, and laughter slams me on my face.

Babies. Children. What is this?

A sturdy woman with a brisk step hurries to greet us. "My lady, you've arrived. Oh, who do we have here?" Her face lights up into a smile as she looks at the baby.

"Another precious gift," Tinsae says before turning to the baby: "You will get your milk, my darling," she coos to the baby, nuzzles their nose with her own, and gives the baby to a woman with a nod.

Then, she turns to me. "I wanted to show you where I work. Well…" She gestures at the place. "This is it."

"What is this place?"

"A place where we raise the babies found on the streets."

"These are all—" I let my gaze run across the room. There are numerous children here. They were all abandoned? In my village, the relatives take care of the orphans. Or those who want to raise orphaned children. Romans just dump them?

Tinsae gives me a sad smile. "Unfortunately, yes."

*fake_choice
    #I'm appalled. They just dump their children on the streets like that?
        *set ruthless -2
        Frown pervades my features as I try to digest this new information. I wanted to think that the baby was an exception.
        
        How could anyone leave their child on the street? The pit of my stomach feels hollow as I look at the children, all of them abandoned, but still smiling and playing. Fighting amongst themselves, their minds occupied by everyday hurdles rather than their fate in this life.
    #I don't know what I expected. Of course the Romans would dump their children.
        I shake my head, completely unsurprised by this revelation about the Roman life.
        
        Just another reason to hate them. Nothing more, nothing less.
        
        However, there's a question that burns the back of my mind: Other than the fact that they are disgusting Romans, why would they do this?
    #Remain silent and look at children running past us.
        Three 5-year-olds run past us while laughing hysterically. An adult chases them with a feature that's mixed with joy and irritation. It reminds me of the time that I chased the twins when they refused to get to bed.
        
        Those children were abandoned, too.

"Why?" I ask.
        
"There are many reasons, all of them tragic." Grief and disgust seep into her voice, despite her expression remaining neutral. "There are prostitutes who are forced to give up their babies or sell them to slavery, there are fathers who don't want a particular baby as a part of their family. The poor might not have enough money to feed another child. It's my understanding that some have hope that a rich family would find the baby."
        
She shakes her head. "That's not what happens usually, I'm afraid."

I'm almost afraid to ask but: "What usually happens?"

"There are slave traders on the streets who pick the babies and—"

"They [i]enslave[/i] babies?"

*fake_choice
    #Now I can't stop thinking about what could've happened to the baby.
        *set ruthless -2
        Little beads of cold sweat start to form on my forehead. If I didn't find them, if I didn't take that shortcut…
        
        *if tinsae_true_name
            "${name},"
        *if not(tinsae_true_name)
            "Hati,"
        Tinsae says with a shake of her head. "Please don't think about what could've happened. It didn't happen to this baby. You saved their life."
        
        "But what about the other—"
        
        "My dear." She caresses a strand of my hair and gives me a smile. "I'm helping the others. You can do that, too."
        
        I nod. I look at the children, now saved from their fate.
    #This makes me think about the twins and their fate...
        I knew the Romans were bad, I just didn't want to stop and think how bad.
    #Again: What did I expect? They are Romans. Of course they enslave babies.
        I merely shake my head in a wholly unsurprised way.
        
        Tinsae gives me a warm smile. "It's better not to think about it."

"What happens to the baby now?"

"They're taken care of. These are good people. I'm paying them well and make sure those who aren't fit for the job will be asked to leave."

"Are there more places like this in Rome?"

"Not many that aren't mine." 

"You have many of these?"

"Yes." She smiles and answers patiently to all of my questions.

"How do you have the money for this?" It must cost a fortune. And this doesn't look like a place that makes any money in return. How could it? The babies don't work.

She gives me another smile. "During my travels, I have become acquainted with many patrons and matrons of note who—"
*page_break
"My lady." A woman with a baby feeding in her arms approaches us. "We are down one wet nurse, Clelia is sick."

Tinsae touches the woman's shoulder with a smile. "Please, don't worry about that. Thank you for your hard work. I will take care of it."

The woman nods and just as she is about to leave, Tinsae stops her: "Have you had time to eat and drink?"

"Yes, my lady. Thank you." She smiles and takes off.

Tinsae shakes her head and scribbles something on her wax tablet.

"My lady! Please, could you hold this little baby for a while, there's a fight breaking out."

A man shoves a little baby to Tinsae. He then runs to the other room where there are shouts of high-pitched violence, clearly a group of toddlers are having a wrestling match. Tinsae looks after the man, seemingly fighting against the instinct to run after him and help. The baby, however, is babbling happily, not minding who's holding them. The baby is having a sermon of a lifetime, it doesn't seem to matter who's listening. Tinsae gives the baby a quick, but no less brilliant, smile before turning to me.

"I'm sorry, I didn't realize it was going to be such a hassle. It's usually quieter this time a day. I—" But before she can continue, the baby starts pulling her hair with a wide smile on their face. Tinsae's face, on the other hand, is slightly distorted in pain.

"Aaah!" She finally lets out a squeal wholly unfit for her.

*fake_choice
    #Try to pry the baby's grip open.
        Without a second thought, I bounce into action. The twins used to tear on father's hair, too. He thought it was funny until they did it from both sides and with a glint of glee on their eyes when father started begging them to stop.
        
        Empathy, the babies truly lack it.
        
        Try as I might, the baby won't let go. They just keep giggling like it's the funniest thing on earth that
        
        "Please be— AAAH!" The baby tears the hair even harder. "Gentle!"
        
        "Me or the baby?"
        
        "Both!"
        
        How can babies have this strong of a grip? The fist is so tiny and chubby, yet it's as if the baby's life depended on keeping a hold of Tinsae's hair.
        
        Finally, and with a tender touch, I manage to unhook the baby's hold. Thank goodness. The baby looks at the big tuft of hair in their hands before starting to laugh like it's the funniest thing they've ever seen in their whole life.
        
        Tinsae sighs. "It's a good thing that I have a lot of hair to pull out. Thank you for the help."
        
        "Not a problem.
    #"What should I do?"
        "I can— AH!— manage," Tinsae says as the baby starts tearing her hair even harder.
        
        "Are you sure?" She does look like she needs help. The pain in her face is now more prominent.
    #Just watch how the situation unfolds.
        "Aren't you going to lend me a hand?" She wheezes under her pained breath.
        
        "I'm not good with babies."
        
*page_break

"Would you mind? I think it's time to have this baby's cloths changed." Tinsae shows the baby and starts to strout towards another room.

I blink. The baby? Cloths? I make a note of the baby's sagging behind.

"Poop?" I ask after her, dreading for the answer.

Tinsae laughs and turns to me. "Unfortunately, yes."

*fake_choice
    #"I'm not good with poop."
        I grimace at the thought. That was [i]not[/i] part of my job description even when I babysat the twins. I made father do it. He didn't want to, either. But I made sure that every time he came back to the house he was met with a demand that he couldn't refuse.
        
        Tinsae turns to me with a raised eyebrow.
        
        "But—" I start.
        
        She raises both of her brows.
        
        "Oh, fine," I mutter and start walking after her. I can't say not to raised brows.
    #"No, I don't deal with poop."
        *if tinsae_true_name
            "${name},
        *if not(tinsae_true_name)
            "Hati,
        I'm asking you kindly."
        
        "But…" I groan.
        
        "Please? You could be my assistant. I won't force you to change it yourself."
        
        "Ugh. Fine."
        
        "Thank you kindly," she says with a bright smile.
        
        "Let's just get this over with."
    #"Sure."
        She turns to me with a smile. "That was easier than I thought it would be."
        
        I shrug. I took care of the poop when the twins were little, it's nothing I can't handle.
        
        "Thank you. You'll make for a great poop assistant."
        
        "…Thank you."
    #"You take care of that, I'll be here waiting." I walk away.
        *set rude +1
        *set tinsae_friendship -1
        "Please, wait a moment—"
        
        But I'm already gone. I'm not spending my day off dealing with poop.
        
        I can almost feel Tinsae's disapproving stare on my back.

*page_break
After the poop ordeal is behind us, I follow Tinsae as she works: she meets some associates of hers, exchanges pleasantries, organizes a search for a missing wet nurse… The day passes by quickly.

A group of laughing children runs past us and Tinsae looks after them with a small smile on her face.

"Now that the most acute problems have been taken care of, do you mind if we went somewhere more peaceful?"

"Sure." 

She gestures me to follow her and we leave to the streets.
*page_break
Tinsae turns to me: "Do you have any preferences?" 

I shake my head. I'm not overly familiar with the town or the surroundings. 

She smiles. "I will show you my favorite spot." She offers me her hand. 

*fake_choice
    #Take it without hesitation.
        *set tinsae_friendship +1
        As soon as she erects her hand towards me, I grab it. She lets out a surprised giggle but doesn't say anything.
        
        I look up to see the evening sun residing behind her. Rays of sunshine frame her.
        
        And I smile at her.
    #Take it after a moment of hesitation.
        *set tinsae_friendship +1
        I look at the hand for a moment, pondering on my next course of action. Should I take it?
        
        Before I can think any further, I notice that my hand is already in hers. Did I give it or did she take it?
        
        I look up to see the evening sun residing behind her. Rays of sunshine frame her.
        
        And I find myself not minding that she has my hand.
    #Shake my head.
        She gives me a smile and retreats her hand. She doesn't take offense.
    #Ignore the hand.
        *set rude +1
        *set tinsae_friendship -1
        She raises her brow at me and lowers her hand. Then, she gives me an awkward smile. "My apologies."

*page_break
She leads me away from the town. We arrive at a river bend.

The trees are bare save for one or two resilient leaves refuse to fall from their branches. It must've been a beautiful place during summer. 

Tinsae takes a blanket out of her bag. She spreads it as close to the river as it's possible without falling into it. Then, with a graceful poise, she sits down.

Quickly enough, I make myself comfortable on the blanket next to her.

It's quiet. Only the sounds of the burbling river fills the cool air. Evening sun warms my cheeks but it does nothing to my freezing limbs.

"I brought some more blankets," Tinsae says and pulls two more cloths from her bag. No wonder it was so big.

Finally, we're wrapped in blankets, looking as the lazily running river passes us by.
*page_break
I close my eyes and take a moment to just listen to the river. It's been a hectic day. The ruckus of the children can be quite taxing to listen to all day. 

We sit in silence for a good while. 

Finally, Tinsae clears her throat to get my attention: "About the baby you found… It's a boy. A healthy little boy." 

"Oh," I say. That's good to hear.
        
"Do you want to name him?"

I raise my brows. "Me?"

"You saved him. I think he wouldn't mind."

That's a lot of responsibility.

"Can I give him any name?"

She raises her brow. "You're not planning on naming the poor boy as a curse word?"

"Oh! No." First his parents abandoned him, then he was named a curse word. That would be too mean.

*fake_choice
    #Give him a Pictish name.
        *set baby_pict true
        "I will name him Toilichte."
        
        "Hm? What does that mean?"
        
        "It means happy in Gaelic. I hope that he's going to be happy, despite how his life started."
        
        Tinsae's eyes start glistening and she looks away with a bright smile. "That is a beautiful thought."
    #Give him a Roman name.
        *set baby_roman true
        "It's better for his future that he doesn't sound too foreign."
        
        Tinsae nods. "That's a good point."
        
        "I'll name him Felix."
        
        "Happy?"
        
        I nod. "I hope that he's going to be happy, despite how his life started."
        
        Tinsae's eyes start glistening and she looks away with a bright smile. "That is a beautiful thought."
    #I can't give him a name.
        I shake my head. "I can't do that."
        
        "Why not?"
        
        "Too much responsibility."
        
        Tinsae smiles and nods. "It is. Nomen est omen. It's understandable to feel hesitant about that. You don't need to do anything you're not comfortable with."

"Do you like children?" She asks.

*fake_choice
    #"Yes." I'm being honest.
        *set child_person true
        *set manipulative -1
        They are innocent and love unconditionally. Also, they're silly little things, always goofing around. Just like the twins were when they were little.
        
        What's not to love? Sure, they can be a handful, but it's worth it.
    #"Yes." I'm lying.
        *set manipulative +1
        I think they are loud and messy. And chaotic. But she seems to like them.
        
        She gives me a smile, unknowing of my deception.
    #"Well, I liked my siblings when they were little. Even though they were little assholes."
        Tinsae starts giggling behind her hand. "Children can be quite a handful."
    #"No. They're really loud and messy."
        *set children_nope true
        Tinsae shakes her head with a smile. "They can be like that."
        
        "You like children?"
        
        "I'd have a terrible job if I didn't."
    #"I haven't thought about that."
        "You're a natural with them." She smiles. 
        
        "I am?" Well, I don't mind children. I suppose that's all it takes.
        
"What made you do this? To help the children?" Perhaps it's a obvious question, she's a good person. No Roman would do what she does.

The smile on her face gets tainted with sadness. "I don't want any child to be begging for money on the street and trying not to get beaten by a drunken passerby. Children are easy targets for adults' ire." Then, her features brighten. "But I couldn't do it alone. There are so many good people who donate, who put our names into their wills…"

"Romans?"

"Yes, of course." She tilts her head slightly, trying to find meaning behind my question.

"I… Why would Romans do anything good?"

Her shoulders relax. "My dear, there are so many good people in this world. Even Romans."

I frown. There are no good Romans. If there were, my family would still be alive.

She's left watching me as I ruminate. Her brows crease in worry but she doesn't say anything.

*page_break
Finally, Tinsae says: "You're a good person."

What? "How do you know that?" I realize how I sound. However, I'm not sure if I am a good person.
*if hatred = "determined"
    I'm here to kill people. No matter the reason, I'm here to kill people. I doubt that makes me a good person.
*if hatred = "manipulated"
    Why am I here, if I'm a good person? What would a good person be doing here? Plotting to kill people. Even if I'm not sure if I even want that, that's why I'm here, right?

Tinsae, however, doesn't see it that way. How could she? Instead, with a widened smile, she says: "I just do."

She tilts her head as she looks at me, unseeing of all the hatred and rage that's been driving me on so far. 

*fake_choice
    #Hatred and rage is all that I am. I'm here to kill people.
        *set tinsae_trust -3
        I don't care if I'm a good person. I don't know what she sees when she looks at me but it's not me. This is what I am. I'm here for my revenge and I will not be swayed from that path. No by her, not by anyone.
        
        I steel my face and look away.
        
        From the corner of my I can see that Tinsae's brows furrow just a little. Finally, she looks away, too.
    #Let her think that I'm a good person.
        *set manipulative +1
        *set tinsae_trust +1
        Whether I think that or not, doesn't matter. If she thinks that's what I am, I can use that information for my benefit. It pays to have allies in this hostile place.
        
        So, I merely smile. "Thank you for saying that."
        
        The smile on her face brightens.
    #Perhaps I am a good person...
        *set tinsae_trust +2
        *comment There are times when my heart wrenches when I think about the pain people go through. Is that a sign of a good person? I'm not sure.
        
        Tinsae gives me a reassuring smile. "I can see it. You need to trust me." 
        
        I suppose I could. If she says it's so, perhaps…
    #I'm not sure what I am.
        I don't know if it even matters what I think. I just am.

Silence falls between us as I ruminate on our conversation. The thought of Romans being anything but a bunch of murdering fools is almost laughable.

*if tinsae_bath
    Then, I remember that I was supposed to talk to Tinsae about something: "Camilla mentioned that you wouldn't mind if I used your bath from time to time."
    
    Tinsae perks up. "Ah. Of course I wouldn't mind. You're welcome to my bath anytime." Then, her expression darkens. "Camilla told me about what happened. That disgusting man didn't have a chance to hurt you, did he?"
    
    *fake_choice
        #"No. He tried, though."
            It's as if a shudder creeps through her as she grimaces. "I'm so sorry. I hope he'll get what he deserves."
            
            "I doubt it," I mutter behind my breath. He's been beating us to a pulp for months now, why would this be the last straw?
            
            Why does Marcus allow it, anyway?
            *if floyd_nooo
                He ordered Floyd to be flogged, too. Disgusting.
                
                "I heard what happened to your friend. He survived?"
                
                "Thankful, yes."
                
                "That's good, at least."
        #I'm still rattled by the whole thing.
            I sigh and look away.
            *if floyd_nooo
                I can't stop thinking about Floyd. I—
            
            Then, Tinsae's soft touch on my hand makes me jerk my gaze back to her.
            
            She gives me a sad smile and a light squeeze. "I'm sorry you have to endure it. You are strong."
            
            At times, I'm not sure if I feel like it. But her gaze almost makes me believe it.
        #"Thank you. For the bath."
            I purposely ignore the question about the Optio. I'm not sure if I want to share my thoughts about what happened. 
        #Remain silent and give her an appreciative nod.
            I don't feel like opening up to her about the Optio at this moment. I'm still processing what happened.

*if tinsae_secret
    I still can't make sense of what Quinn said. $!{q_he} seems so sure that Tinsae is threatening our lives, yet I can't see it. What is there to see?
    
    "What is it?" She asks with a curious smile. The smile lacks any threat, it doesn't seem to have any hidden intentions behind it.
    
    Is she more cunning that I give her credit for? Why is Quinn so afraid of her?
    
    *fake_choice
        #I believe in Quinn. $!{q_he} must see something I can't see.
            *set quinn_trust +1
            *set tinsae_trust -1
            I purse my lips and harden my resolve. $!{q_he} knows what ${q_he}'s talking about. $!{q_he}'s had a direct contact with the Twins, after all.
            
            Even if I can't see it.
        #Quinn must be mistaken.
            *set quinn_trust -1
            I'm not sure what drove ${q_him} to dislike her but whatever it is, I can't see it. $!{q_he} could just be wrong about this one. It's understandable that ${q_he} sees threats where there aren't any. We're in a difficult situation, surrounded by enemies.
        #Could Quinn be jealous?
            Would ${q_he} be so petty? But why isn't ${q_he} jealous over the others? Besides, it would be for the mere fact that I'm talking with Tinsae.
            
            It doesn't sound like Quinn. The stressful situation must've made ${q_him} more suspicious. If that's the case, I suppose I can't blame ${q_him}.
        #I find myself not caring about Quinn's opinions. And it hurts.
            *set quinn_trust -2
            $!{q_he}'s changed. The thought stings my heart but it is what it is. I don't dare to rely on ${q_him} anymore. 
    
    "What's wrong?" Tinsae asks.
    
    "Nothing," I lie. Something is wrong. I just don't know what.

*page_break
*if tinsae_siblings
    "I've been meaning to tell you something."
    
    "Hm?"
    
    "As you know, I've been searching for your siblings."

    Hope perks me up. "And?"
    
    "I have a lead." She gives me a reassuring smile and a nod. "I'm close to finding them. There is hope."
    
    *choice
        #Give her an appreciative nod.
            I exhale in relief. Thank the Twins. I knew she was the one who'd find them.
            
            She has connections. If she didn't find them, who would?
            *goto ch5_tinsae_travelling
        #"Thank you so much." Tears starts to gather on the corners of my eyes.
            It frustrates me to no end that I can't find them myself. I can only trust in strangers. 
            
            And this one stranger has shown me only kindness so far.
            *comment keskustelua sisaruksista?
            *goto ch5_tinsae_sibling_hug
        #Hug her.
            *goto ch5_tinsae_sibling_hug
        #"Thank you. I hope it's not too late."
            "Please, don't think about that. We simply don't know yet."
            
            I nod. I can't help but feel a little pessimistic.
            *goto ch5_tinsae_travelling
            
*label ch5_tinsae_sibling_hug
"Oh, dear. Come here," Tinsae says and opens her arms, inviting me into her embrace.

*fake_choice
    #I quickly slip into her arms and bury my face in her dress.
        I do so without thought. Her arms are inviting, my heart needs warmth and intimacy she's so readily offering.
        
        I nestle myself in her arms and close my eyes as her sweet perfume surrounds me. Her stable breathing calms me, her silken dress caresses the skin of my cheek.
        
        "I will find them," she whispers into my hair, her lips tickling my skin.
        
        My mind fills with gratitude.
        
        "Thank you," I whisper.
    #I shake my head but secretly want to bury myself in her arms.
        She tilts her head and gives me a little smile. "Are you sure?"
        
        I pout my lips. No. I'm not. 
        
        Chilly Northern wind bites my skin and chases me to move closer towards her, partly hoping that she would meet me half-way.
        
        She does. She leans towards and takes a gentle hold of my shoulders, guiding me towards her.
        
        "Come here," she whispers against my hair. "You're so cold," she says and wraps her blanket around me tightly.
        
        I nestle myself in her arms and close my eyes as her sweet perfume surrounds me. Her stable breathing calms me, her silken dress caresses the skin of my cheek.
        
        "I will find them," she promises. And I find myself believing her.
    #I shake my head. I don't want a hug.
        She leans back and gives me a nod. "I will find them." Her gaze is soft as she looks at me, her eyes are filled with determination.
        
        I find myself believing her. She will find them.

*goto ch5_tinsae_travelling

*label ch5_tinsae_travelling
She's been talking about her other establishments, she must travel a lot. I ask, and she answers:

"Yes. I need to." She looks wistfully at the river. Its running waters could carry her off to another country. Her gaze follows the water till she can't see the end of the river. "There are many matrons to stay connected with, many men like the Legate to do business with."

"So, you're not planning on staying here?"

She turns to me with a smile. "No." It's a simple answer, lacking any possible implications or hidden feelings. "It was never my intention."

I nod. She's always ready to leave.

*choice
    #For some reason, hearing those words makes me feel bad.
        *set tinsae_friendship +1
        *goto ch5_tinsae_leaving_nuu
    #I shrug. That makes sense. She's a traveling merchant.
        *goto ch5_tinsae_leaving_understandable
    #"I will miss you." I'm being honest.
        *set tinsae_leave_noo true
        *set manipulative -1
        *goto missing_tinsae_ch5

*label ch5_tinsae_leaving_understandable
I give her a nod. I knew she would leave. I'm not sure how long I'll be here, either. That's life.
        
She gives me a relieved smile. "Thank you for understanding."

We sit in silence for a good while. Then, cold starts to find its way beneath the blankets and it's time to go home.
*set ch5_met_someone true
*page_break
*goto ch5_met_someone

*label ch5_tinsae_leaving_nuu
*set tinsae_leave_noo true
I don't know why, but I find myself creasing my brows. In thought, perhaps. 
        
Then, I almost chuckle to myself. Why did this come as a surprise? That a traveling merchant would actually travel? Despite that, however, there's still a layer of uneasiness within me. Like there's something in the pit of my stomach. A knot of sorts, tightening with the rhythm of my heartbeat.
        
"When are you leaving?" I ask, partly to draw my attention away from it.
        
"Next spring."
        
"Where?" Why am I asking? Why does hearing that make my hear feel heavy? Why does the thought of her leaving make me feel… weird?
        
She gives me a smile, but this time the smile is hiding something. It's coated with warmth, but there's something else underneath. "I'm not sure." She looks away. "I'm needed in many places."
        
Both of us fall silent, only the freezing wind murmurs in my ears with the bubbling of the moving water. I tighten my blanket and fix my gaze on the river.
*comment
*choice
    #"I will miss you."
        *set manipulative -1
        *goto missing_tinsae_ch5
    #Remain silent and ignore the feeling.
        I choose to ignore it. That's the way to deal with any and all feelings. 
        
        She gives me a little frown. 
        *if tinsae_true_name
            "${name},
        *if not(tinsae_true_name)
            "Hati,
        are you sure you're alright?"
        
        I nod. Of course I am. I'm never anything else than alright.
        
        From the corner of my eye I see her tilting her head at me. Then, she smiles. "I see."
        
        She doesn't say anything else. Instead, she looks at the river.
        
        "Would you do me a favor?" She asks.
        
        "What?"
        
        "Would you listen to the river?"
        
        I give her a doubtful gaze before deciding to humor her. So, I try to listen to the river.
        *goto ch5_tinsae_river

*label missing_tinsae_ch5
The words leave me before I can think any better. It's the truth. I… I don't want to think about her leaving.
        
She gives me a warm look. Looking at her, knowing what I know now, that look must be one she's given to many others in different towns. To many different people in different phases in her life.
        
"You don't need to worry about the future, my dear." Her eyes are filled with intensity as she looks at me. The words are sweet, urging me to forget about the future and focus on the presence, instead.
        
*fake_choice
    #She gives me a little peck on top of my head.
        She takes a hold of my shoulder and gently pulls me towards her. The scent of a flower bed overcomes me, as if summer itself greeted me in the midst of the freezing coming of winter.
        
        She kisses the top of my head. Her kiss is soft and light, and like the rays of sunshine, her slow exhale warms the skin of my scalp. Instinctively, I close my eyes and take in her warmth. She gently squeezes the  
        
        "I'm here now," she murmurs against my hair. "And so are you." 
        
        Her words ground me into this moment. It almost makes me forget about everything.
        
        I close my eyes, hearing only her steady, slow breathing, and the bubbling of the river as it passes rocks and branches. There's the earthy smell of algae on top of the rocks. The scent of her floral perfume lingering around us.
        
        I'm here now. With her.
    #She examines my features with warmth.
        "Do you hear that?" She turns her attention to the river. "How the stream of water bubbles over rocks."
        *goto ch5_tinsae_river
    #I look away. I'm afraid of getting hurt by her but I refuse to tell her that.
        "Do you hear that?" She turns her attention to the river. "How the stream of water bubbles over rocks."
        *goto ch5_tinsae_river
    #I look at her. I'm afraid of getting hurt by her.
        *goto ch5_tinsae_leave_hug
        I fear. I fear of hurting when she leaves. I've hurt too much already, I don't want to hurt again.
        
        She take a shaky breath before giving me a smile. "Oh, dear. Please, can I give you a hug?"

*label ch5_tinsae_river
*page_break
I look at the river.

From the corner of my eye I inspect Tinsae, waiting for what's next to come.
        
"Close your eyes," she says. "You can hear better that way."
        
I do as she asks and wait, not quite sure what to expect.
        
Then, the sounds of the river running freely pass us fills my ears. Not only that, but there's also the earthy smell of algae on top of the rocks. There's her warmth next to me, her floral perfume lingering around us. The scent of her reminds me of summer.
        
She says in a low, soft voice: "I'm here now. And so are you."
        
I find myself nodding. I'm here now. With her. 
        
We're both still here.
*set ch5_met_someone true
*page_break
*goto ch5_met_someone

*label ch5_tinsae_leave_hug
*page_break
I fear. I fear of hurting when she leaves. I've hurt too much already, I don't want to hurt again.
        
She take a shaky breath before giving me a smile. "Oh, dear. Please, can I give you a hug?"

*choice
    #I shake my head. I don't want to be hugged right now.
        "That's alright, too." She smiles. "We can just sit here and listen to the river." 
        *goto ch5_tinsae_river
    #I shake my head. It might hurt too much when she leaves.
        I can't hug her. If I continued to get too close to her and she ended up leaving, anyway… How could I manage?
        
        She gives me a little nod and a slight smile. "I understand." Then, she turns her attention to the river. "Do you hear that? How the stream of water bubbles over rocks."'
        *goto ch5_tinsae_river
    #I nod.
        I give her a quick nod and she closes what little distance there was between us. She wraps me into her embrace, inside her blanket, making me doubly blanketed.
        
        The scent of flowers and nuts overcomes me and I find myself closing my eyes. I lean into her embrace, press my head against her soft bosom.
        
        I listen to her peaceful heartbeat.
        
        Her slow exhale warms the skin of my scalp.
        
        "I'm here now," she murmurs against my hair. "And so are you." 
        
        Her words ground me into this moment. It almost makes me forget about everything.
        
        I listen to her steady, slow breathing, and the bubbling of the river as it passes rocks and branches. There's the earthy smell of algae on top of the rocks. The scent of her perfume linger around us.
        
        I'm here now. With her.
        *page_break
        *set ch5_met_someone true
        *goto ch5_met_someone

*label ch5_date_camilla
Tinsae gave me a tip that Camilla should be at a nearby tavern at this hour.

The tavern is located on the periphery of the town. Shady-looking people exit the tavern. Is this really where Camilla is supposed to be?

Tinsae said that it's the only tavern in the area and you should expect a surprise.

Well, I'm here and I'm already surprised.

Then, something catches my eye, something lies on the ground near the entrance. A man hopped over it and continued walking.

I walk closer and frown.

There's a man in rags lying face down on the ground. His arms are twisted in an unnatural way. 

*fake_choice
    #Check his pulse.
        *set ruthless -1
        I quickly check his freezing wrist for a pulse.
        
        Nothing.
        
        I didn't expect to find anything, I suppose. He looks badly beaten.
        
        I can't do anything about this. I quickly recite a prayer to the Twins and proceed to the tavern.
        
        I'm sorry, old man. May you find peace in the afterlife.
    #Nudge him with my foot.
        He definitely looks dead. Still, I poke his body with my foot, half-expecting — and hoping — him to get up with a groan and telling me to piss off.
        
        Nothing. As expected. He's definitely dead.
        
        There's nothing I can do. I think of reciting a prayer to the Twins but decide against it. I hope he has the attention of benevolent gods to help him in the afterlife. 
    #Ignore him and continue inside.
        *set ruthless +1
        He looks dead to me. I can't do anything about the situation.

*page_break
The tavern is dark save for a few braziers and lanterns. The smoke is prickling at the back of my throat and stinging my eyes. The establishment is clearly meant for people with lower income.

"Excuse me," I say to a woman beside a blazing furnace.
    
She gives me a drained look. There's no trace of any customer service smile, just a sneer. "What?"
    
"There's a dead man near the entrance."

"Again?" She sighs and turns to shout at someone. "Hey, Aulus! There's trash at the entrance!"

*fake_choice
    #"Excuse me? He's a human, not trash."
        *set ruthless -5
        How dares she call someone trash? 
        
        She turns back to me, her face filled with disdain. Then, she scoffs: "Did you know the guy?"
        
        "No. But—"
        
        "Then who the fuck cares? I have enough in my hands without worrying about some dead beggars."
        
        I'm left staring at the woman. How is anyone this callous? 
            
        A Roman, that's who. Rude and ruthless. I should've expected nothing less.
            
        "Well? You want a drink or not?"
    #Is she talking about the man? Give her a stink-eye.
        She shrugs. "What?" 
    #Whatever. I'll head to the table.

*page_break
There are only a couple of chairs and they are all taken. The poor should apparently stand while drinking. I eye at the other customers. Men and women mingle without a trace of any posh etiquette that guides the Romans I've surrounded myself with. The people in the tavern don't seem to care if someone sees their naked skin. Or if someone touches another's tunic. Or if someone sees them drinking, kissing. It's as if the code guiding the people in the streets don't exist here. Or people don't care.

They seem to be completely free to do whatever they want.

There's still the same scent of perfume that I've grown used to but the smell is more pointed, it has an edge to it. It's mixed with the smoke and sweat.

"Oh, a soldier." A cooing voice calls to me. A woman flutters her eyelashes. Her wig is disheveled and her dress a little stained. But her poise is proud and her speech pleasant to the ears.

She's dressed in a toga for some reason. I've only seen men in togas before. On top of that, she wears it differently from the men that I've seen: the fabric is partly over her head. There's something different about this woman.
    
She gives me time to assess her before giving me an approving nod.
*if not(appearance_chosen)
    *set appearance_chosen true
    *fake_choice
        #"Hi there, handsome."
            *set handsome_gremlin true
        #"Hi there, pretty boy."
            *set pretty_gremlin true
            She takes a moment to admire… me, I suppose. "You almost look like a beautiful woman."
        
            *if sex = "female"
                Well, I certainly hope I don't.
            "Thank you?" I suppose.
        #"I love rugged men."
            *set rugged_gremlin true
            Oh? I suppose I should take that as a compliment?

*if appearance_chosen
    *if handsome_gremlin
        "Hi there, handsome." She licks her lip and looks at my frame.
    *if pretty_gremlin
        "Hi there, pretty boy." She tilts her head and looks at my face. "You're beautiful for a man."
    *if rugged_gremlin
        "Hi there." She tilts her head and looks at me. "I love rugged men."
    
"Would you like to spend some time with me? I swear you'd have a good time."

*fake_choice
    #"No, thank you." I'm aware what she means and I'm not interested.
        *set rude -1
        I give her a small smile as I politely decline the offer. She looks me up and down before smiling. "Suit yourself, soldier. Have good day."
    #"What sort of a good time are we talking about?" I honestly have no idea what she wants from me.
        *set clueless +2
        She's clearly selling something, that much I can gather from her demeanor. She's not carrying anything, though. There is no merchandise in sight.
        
        She gives me a blank look before shaking her head and letting out a little giggle. "Please excuse me, I thought you were serious."
        
        I frown. "I am serious. What is it that you want from me?"
        
        She blinks, her smile is frozen on her face. Then, she shakes her head. With her head tilted while wearing a gentle smile she says: "Nothing, darling. Please, have a good night."
        
        She saunters off with her hips swaying extravagantly.
    #A prostitute. "How much?"
        This is hardly the time but I'm interested.
        
        "15 asses for you, darling." 
        
        That's cheap. Why would she sell herself for so little?
        
        I shake my head. "I would pay you more."
        
        A bright smile illuminates her face. "How kind of you, my Lord." She takes a step closer to me, her mouth narrowly open.
    #A prostitute. "Why are you selling yourself?" I'm not judging, just curious.
        *set ruthless -2
        *comment achievement
        She tilts her head. "Are you new here, darling?"
        
        "Well, yes." It must be obvious.
        
        She gives me a smile. "Do you want the truth or a sweet lie?"
        
        "Truth, please."
        
        "I don't have any other means of getting money, my Lord. But I'm very good at what I do."
        
        "Oh." That's unfortunate. "So you don't want to do this?"
        
        She sighs. I realize that I'm taking her time without meaning to pay her. "I, uh… Here's 30 denarii. Would you tell me now?" I hand her some money with a reassuring smile.
        
        Her mask falls as she gasps with widened eyes. "My Lord! I couldn't…" She frowns and looks at me. "Are you sure?"
        
        I nod. Was that too much? She looks like she needs it.
        
        It's difficult to see in the dark but her eyes seem to gather the beginnings of tears. She quickly flutters her eyelids and gives me the widest smile I've seen in a while. "Thank you, my Lord. I have two children. They're at home and… thank you. I can invest this money into their future. Thank you so much."
        
        Oh. That's good. "I'm glad to hear it."
        
        "My Lord, is there anything I can—?"
        
        "No, I don't need anything."
        
        "Then, I will go to my children. Thank you again." She gives me the last incredibly wide smile and leaves.
    #"I don't know what you're selling but I want none of it. Sod off."
        *set clueless +2
        *set rude +2
        I don't know what she wants but I have no time for it.
        
        She throws me a pointed look before walking away. 
    #"I don't want anything from you. Sod off." I know what she wants and I'm not interested.
        *set rude +2
        She throws me a pointed look before walking away. 

*page_break
Then, a woman appears from out of nowhere. Her presence manages to capture even the loudest of customers' attention. She moves with silent purpose, her poise is proud. Her short brown hair is flowing free, she's holding a lute in her hands. There's a cheap couch in the middle of the tavern, clearly meant for performers. She takes a seat with grace, her chin held high, her lightly tanned skin illuminated by the lantern next to her.

Camilla.

She's not clothed in her usual attire. 
*if hobby_fashion
    There's no sign of her stola, nor her silken dress. Instead, she wears a simple long tunic and a cloak.
*if not(hobby_fashion)
    The dress that seemed to be made of miles of fabric is gone. Instead, she wears a simple dress and a cloak.

She doesn't smile at the audience waiting for her to start. It's as if she's ignoring them. It's as there's nothing but her lute and her. She plays a few notes, then, as if content with the sound, she starts playing a song.

The tune is simple, yet alluring. The notes dance in the smoky air, mingling with the odd sounds of crackling fire. Her eyes are closed as she takes a breath and starts singing.

The words are clear but fragile, as if they might dissolve into the thick air. There's a little crack when she sings of those gone from the land of the living; buried deep beneath the ground, torn from their loved ones before their time. Sorrow seeps from her words, dripping grief and anguish.

She hums the rest of the lyrics. She sings without words, the melancholy deeply ingrained in her voice.

"Oi! Sing something cheery!" Someone shouts.

*fake_choice
    #"Shut up!" I shout back at him.
        *set disciplined -1
        *set camilla_friendship +1
        A fierce need to protect the moment takes over me and I shoot the man with a deadly glare. He falls silent but squints his eyes at me. 
        
        Meanwhile, Camilla ignores the commotion. She does, however, throw a little glance at me. She seems to be unaware of who I am, since there's not a sign of recognition in her gaze. Instead, she keeps singing.
    #Glare at the man. Don't you dare to ruin her moment.
        *set camilla_friendship +1
        A fierce need to protect the fragile moment takes over me and I shoot the man a deadly glare. He squints his eyes at me and stops shouting.
        
        Camilla ignores the commotion and keeps on singing.
    #Ignore him.
        *set disciplined +1
        Camilla ignores the commotion and keeps on singing.

Once the sorrowful song is over, she ends up playing a couple of happier tunes, most likely to appease the drunken crowd. Her heart is not in it and still there's no smile on her face, despite the joyful lyrics.
*page_break
Finally, she nods at the crowd and stands up. I half expect her to tell the people to sod off. She's done.

With some haste, I stand up to reach her before she leaves. However, it seems that I'm not the only one. The man who shouted before is already taking long strides towards Camilla.

With a slight frown I follow him. It doesn't look like he has anything good in his mind.

Camilla gives the approaching man an icy stare before turning to leave. That manages to anger the man.

"I just wanted to ask if you took offense to my shout. Aren't you a stuck-up bitch."

Camilla ignores him and starts walking away. He, however, acts quickly and ends up taking a tight hold of her arm. Camilla looks at him with bared teeth.

"If you don't let go of me, you worm—"

"What does a little woman like you think she can do to me?"

*choice
    #Intervene with violence.
        "Hey, asshole!" I shout and by the time he looks at me, I punch him in his face.
        
        A crunching sound follows. Something broke.
        
        He falls backwards
        *if ((build = "heavy") or (build = "average"))
            and lands on the floor, groaning in pain.
        *if (build = "lithe")
            but manages to remain standing. He bends down and groans.
            
        Camilla looks at the man. Then, she looks at me. Her eyes widen.

        "You," she says, clearly not happy with what she sees.

        "Hello."

        The man still groans between us. Camilla turns her attention to him. Then, with a sneer tainting her face, she kicks him on the shin
        *if (build = "lithe")
            making him fall on the ground.
        *if ((build = "heavy") or (build = "average"))
            . The man groans a little louder.
    
        She shakes her head and scoffs. Then, she starts walking. She gives me a quick glance before leaving, indicating that she wants me to follow her.
        *goto ch5_camilla_sing
    #Intervene with words.
        "Let the her go," I say in the most commanding tone I can muster.
        
        He turns to me, looking ready to start a fight.
        
        "What does a squid like—" There's a sound of something breaking and the man falls limp on the ground.
        
        Camilla stands behind him. She hit him with a clay jug.
        
        She shakes her head and scoffs. Then, she starts walking. She gives me a quick glance before leaving, indicating that she wants me to follow her.
        *goto ch5_camilla_sing
    #Don't intervene.
        *goto ch5_camilla_throat_punch

*label ch5_camilla_throat_punch
I merely watch how the situation unfolds. I'm sure she can handle herself. She will probably turn the man into stone with her hateful gaze.
        
Camilla squints her eyes at the man. Then, with speed that I didn't think she'd be able to muster, she yanks herself free, and punches the man in the throat.
        
He falls on the ground like a stone with a loud thump and a painful groan.
        
Camilla throws him a disgusted look. Then, she turns her attention to me, clearly ready to curse me off, too. Then, her eyes widen with recognition. The disdain loses some of its edge and her posture relaxes a fraction. 
        
"Oh, it's you."
        
I nod. I look at the man between us. He's groaning.
        
With a sneer she says: "He'll survive. Or not." She starts walking away. I follow her with some hesitation. The man still groans, and shows no sign of standing up.

*fake_choice
    #"Throat punches can be lethal. What if you killed him?"
        *set ruthless -1
        Camilla turns to me with a frown. "Are you serious?"
        
        When I give her no indication that I'm kidding, she scoffs. "What do I care?" She looks at the man with a frown. If I didn't know better, I would be fooled to think that there's a layer of hesitation in her gaze.
        
        "I…" The frown on her face deepens. "Do you think he will die?"
        
        I shrug.
        
        She purses her lips and still hesitates. Then, she scoffs. "We can't be seen here if he has friends nearby." With these words, she starts walking away. 
        
        I take one more look at the man before following her. I doubt there's anything I could do to him.
    #I stay behind and ask if he's alright.
        *set ruthless -1
        "Excuse me?" I say.
        
        Another groan is my only answer.
        
        Camilla walks back to look at us. "What is it?"
        
        "What if he dies? Punching someone in the throat can be lethal."
        
        "Wh—" She frowns. "Are you serious?"
        
        When I give her no indication that I'm kidding, she scoffs. "What do I care?" She looks at the man with a frown. If I didn't know better, I would be fooled to think that there's a layer of hesitation in her gaze.
        
        "I…" The frown on her face deepens. "Do you think he will die?"
        
        I shrug.
        
        She purses her lips and still hesitates. Then, she scoffs. "We can't be seen here if he has friends nearby." With these words, she starts walking away. 
        
        I take one more look at the man before following her. I doubt there's anything I could do to him.
    #Follow her.
        With a shrug I start following her. The man groans after us, it's difficult to know if he's able to breathe or not.

*goto ch5_camilla_sing

*label ch5_camilla_sing
"I didn't know you sing."

The tips of her cheekbones are tinted pink as she looks away. Then, as if ready to challenge me, she turns to me with vengeance. "You've got a problem with that?"

*fake_choice
    #"No. It think you sounded beautiful."
        *set camilla_friendship +1
        She steels her gaze and waits for something more. Something insulting, probably. Something to justify her counter-attack.
        
        When I say nothing more, she creases her brows. "Are you serious?" 
        
        "Why wouldn't I be?"
        
        Her frown deepens. She looks away with pursed lips. "I…" 
        
        She searches for the right words, her demeanor unusually flustered. Others would barely notice her bewildered state, she merely glances at the door and swallows lightly, but I've already studied her for couple of months.
        
        Finally, after a moment of squirming, she whispers: "Thank you."
    #"Not exactly. It's just... not what I expected."
        She purses her lips, clearly unsure what to say. "Why? Didn't think I could sing?"
        
        "I hadn't thought about that."
        
        "I suppose you wouldn't…," she says, more so to herself than me. She looks away, trying to reach for her wig's long curls, only to grasp for air. Then, she asks: "What did you think?"
        
        "Of your singing?"
        
        "No, my dress." She rolls her eyes.
        
        "Now now. No need for sarcasm."
        
        *fake_choice
            #"It was pretty."
                "Pretty?" She wrinkles her nose at the word. 
                
                "Yes. You sound pretty."
            #"It was beautiful."
                She looks at me with a frown still lingering on her features. Then, a little smile creeps in. 
                
                Before the smile can blossom, she grimaces almost comically to stifle the smile out of its breath.
                
                "Thank you," she says with tight lips.
            #"Eh."
                The redness on her cheekbones deepens in color. This time, however, it's a sign of rage that she's barely managing to keep inside.
                
                "Eh?"
                
                I nod. 
                
                She seems to be biting her tongue in order not to lash out at me. 
            #Remain silent.
    #"It's weird seeing you perform to the local drunkards. What would the Legate think?" I smirk at her.
        If a look could kill, I'd probably be dead.
        
        "If you think you can tell Gaius that I'm here…" She snarls between her teeth.
        
        "I didn't say I would tell on you."
        
        She squints her eyes.
        
        "That's a good idea, though. Perhaps I should…"
        
        "If you tell him, I'll tell that you tried to grope me. They'll execute you."
        
        "Oh?"
        
        "Want to try your luck?"
        
        She would do it. Without hesitation. "No, I'll pass."
        
        Groping? That's where her mind went?
        
        "What are you smirking?" She squints her eyes at me.
        
        "Absolutely nothing."
    #Shake my head.
        She squints her eyes at me, steeling herself for something else. But there's nothing else to say. I don't have a problem with her singing.
        
        She looks away. "Well… good."

"I, uh…" She bites her lip, clearly so hard that she must taste her own blood by now. "You won't tell the others what you saw."

It almost sounds like a question. If she was in her element, it would've been a command.

*fake_choice
    #"Is that an order or a question?"
        "An order, of course!" She barks with her voice pitching. Then, she sighs, clearly collecting herself. "Are you enjoying this?"
        
        "Perhaps."
        
        "Hm. You remind me of Marcus."
        
        "Ugh." That's a low blow. 
        
        She smirks in content.
    #"Of course I won't." I'm telling the truth.
        *set manipulative -1
        Some of the tension leaves her body. She lets out a little exhale, clearly trying to collect herself. 
    #"Of course I won't." I'm lying. I will probably tell.
        *set manipulative +2
        Knowing something about her that she wouldn't want others to know… This is gold. I'm happy that I came here.
        
        She peers at me with distrust coating her gaze. Then, she shakes her head. 
    #"We'll see." I tease her. 
        She frowns. "Are you trying to be funny?"
        
        "Perhaps."
        
        "You and Marcus share that feature."
        
        "Ugh." That's a low blow. 
        
        She smirks in content.
    #Nod.
        Some of the tension leaves her body. She lets out a little exhale, clearly trying to collect herself.
        
        "Thank you," she says with an oddly appreciative nod.

*page_break
Camilla shakes her head, takes her lute, and starts walking towards a staircase. She seems to be going upstairs. Is her room there?

She turns to me, evidently annoyed that I'm not following her: "Well? Are you coming or not?"
*comment
*choice
    #Why must she be so rude? It's getting old.
        *goto ch5_camilla_rude
    #Shrug and follow her.
        Might as well, I'm already here.
        *goto ch5_camilla_room

*label ch5_camilla_rude

I mutter to myself and follow her.
        
It's as if she can sense my annoyance, for she turns to me. "What is it?"

*fake_choice
    #Confront her about her rudeness.
        *comment variantti
        "You're rude."
        
        She frowns at the words. "How is that new?"
        
        "It's most definitely not new. And I would prefer if you lose the attitude."
        
        She looks away, seemingly weighing on my words. Then, she nods. "You're right."
        
        Then, she starts walking to upstairs. When I don't follow, she turns to me. Through gritted teeth she says: "Would you [i]please[/i] follow me?"
        
        That word almost doesn't fit her mouth.
    #Mutter to myself and refuse to answer.
        I mutter to myself something about rude Roman noblewomen, unnecessary boorishness from people who should know better—
        
        "What are you muttering about? Speak up if you have something to say."
        
        I just squint my eyes as an answer.
        
        She looks at me as if she genuinely has no idea what my problem is. With a shake of her head, she proceeds towards the stairs. I follow her, only because I'm already here.
    #Shrug and follow her.
        It's not worth it. Could she even be anything but rude? It's difficult to imagine.
        
        She gives me a raised eyebrow and starts walking.
   
*goto ch5_camilla_room

*label ch5_camilla_room
*page_break
The corridor she leads me to is pitch black, save for a couple of lanterns futilely trying to illuminate the area. There's a little window but the evening sun does nothing to compete with the suffocating blackness. From what little I can detect in the darkness, the stone walls look greasy to the touch. With my eyes squinted, I can see graffiti on the walls.

Then, a moaning voice intrudes the silence. At first, I think someone is in peril. Then, after another moan, I realize that it's something else entirely.

Someone is apparently having sex. In a room close by.

Camilla ignores the voices, as if it's a normal soundscape around here. 

*fake_choice
    #The sounds, the environment... I'm repulsed by this situation.
        *set sex_repulsed true
    #I follow her, trying not to mind the sounds.
    
*if sex_repulsed
    Another moan makes me almost turn on my heels and leave. Camilla, however, turns to me with a questioning gaze.
    
    "What is it?"
    
    "Why are we here?"
    
    "I just wanted to talk somewhere more private."
    
    Ugh. With a shake of my head I follow her into a small room, which is protected only by a flimsy excuse of a door. 
*if not(sex_repulsed)
    She leads me to another room, protected only by a flimsy excuse of a door. 
*page_break
I grimace at the sight of the room. It's not absolutely disgusting but it's not far from it. There's a phallic-shaped lamp in the corner. Of course there is. There are more graffiti on the walls. One of the biggest ones says that they "fucked Julia from behind in this room". There's a little signature below the announcement, it seems that a fellow called Marius was on the case.

*if sex_repulsed
    "Oh for crying out loud," I mutter to myself and look away.

    "What is it?" Camilla tilts her head at me, repeating the previous question, clearly trying to read me but failing to do so.
    *choice
        #"I don't like sex stuff."
            *set manipulative -1 
            "'Sex stuff'?" She blinks at me.
            
            Another silent moment is stolen by the moaning couple. I shift my weight and try to look away only to realize that there are penises drawn all over the room.
            
            She looks around the room, too, before giving me a nod. "I see. I understand. I'm sorry I brought you here. I think that the couple will be finished soon."
            
            "Why are we here anyway?"
            
            "No one bats an eye at me while I'm here. I'm invisible."

            "But… it's disgusting. When was the last time anyone cleaned here?"

            "I'm not sleeping here. I can wash my clothes at home." She shrugs again. "Besides, Gaius would never follow me here."

            Hm. That's certainly a good point. I definitely wouldn't have followed her here either if I knew.
            *goto ch5_camilla_why
        #"This is making me uncomfortable."
            *set manipulative -1
            "The room?" She asks as another moan comes from the room next door. "Oh. I didn't realize."

            Another silent moment is stolen by the moaning couple. I shift my weight and try to look away only to realize that there are penises drawn all over the room.

            This is highly uncomfortable.

            "I'm sorry I brought you here. I think that the couple will be finished soon."

            "Why are we here anyway?"
            
            "No one bats an eye at me while I'm here. I'm invisible."

            "But… it's disgusting. When was the last time anyone cleaned here?"

            "I'm not sleeping here. I can wash my clothes at home." She shrugs again. "Besides, Gaius would never follow me here."

            Hm. That's certainly a good point. I definitely wouldn't have followed her here either if I knew.
            *goto ch5_camilla_why
        #I shake my head. Nothing. "Why are we here?"
            "No one bats an eye at me while I'm here. I'm invisible."

            "But… it's disgusting. When was the last time anyone cleaned here?"    

            "I'm not sleeping here. I can wash my clothes at home." She shrugs again. "Besides, Gaius would never follow me here."

            Hm. That's certainly a good point. I probably wouldn't have followed her here, either, if I knew what kind of establishment this is.
            *goto ch5_camilla_why
*page_break
*fake_choice
    #Look away with my cheeks tinted red.
        *goto ch5_marius_shy
    #Nod approvingly.
        *goto ch5_marius_nod
    #Ignore it.
        "You're probably wondering why we're here." She looks at the walls.
        
        I nod.
        
        "Nobody knows me. Nobody cares. Gaius wouldn't dare to follow me, even if he suspected that I'm here."
        
        That makes sense. It's difficult to imagine the Legate barging in here.
        *goto ch5_camilla_why

*label ch5_marius_shy
Why oh why are the Romans such prudes? Why would anyone think to write that for everyone to see? Did this Marius just do the deed and then started scribbling on the wall? Did Julia just wait on the bed for him to be done with it? I hope the poor woman left and never came back.
        
Ugh. Stupid Romans.
        
I take another quick look despite the warmth on my cheeks. I could swear that I saw something scribbled underneath the text… Is that a…

Oh, for Twins' sake, it's a penis! A humongous penis. Marius probably wants us to believe it's his.
            
I look away again, this time in irritation. Why did I look? I knew what a guy like Marius would draw underneath such declaration.
*page_break
    
I just realize that Camilla's been looking at me the whole time. She looks at my cheeks and gives me the tiniest of smirks.
    
"Isn't this an interesting room?"
    
"Interesting?" That's one way to look at it, for sure. My gaze wanders to the other graffiti: every one of them is a declaration of coitus that took place.
    
"Mainly prostitutes use this room."
    
I almost groan at the sound of that. "Why would you want to come here?"
    
She shrugs. "No one bats an eye at me while I'm here. I'm invisible."

"But… it's disgusting. When was the last time anyone cleaned here?"

"I'm not sleeping here." She shrugs again. "Besides, Gaius would never follow me here."

Hm. That's certainly a good point. I probably wouldn't have followed her here, either, if I knew what kind of establishment this is.
*goto ch5_camilla_why

*label ch5_marius_nod
*if shy_perv
    I quickly glance at the graffiti and find myself nodding at it. I do so discreetly, hoping that Camilla doesn't notice.
    
    Good for Marius. I hope Julia enjoyed her time, as well.
    
    "What are you nodding at?" Smile rings through Camilla's words.
    
    "Nothing."
    
    "Uh-huh." She doesn't look like she believes me.
    
*if brazen_perv
    I peer at the graffiti with interest. Hmm. I see. Other graffiti declare the same thing but with a different man and a different position. 
    
    Some brave soul even admits that he sucked someone called Albus off.
    
    Those Romans who'd like to appear masculine wouldn't suck anyone off, from what I've understood. They'd have to be the one to be sucked on.
    
    Interesting.
    
    "You're curiously interested in the walls," Camilla says with a little smile dancing on her lips.
    
    I shrug. "It's interesting. How overtly sexual you Romans are."
    
    "Hm. Some men, yes. Not all of them, of course, the ones who want to be heard. We noblewomen, however, are expected to behave ourselves." She gives me a little smirk. 
    *fake_choice
        #"Do you? Behave yourself?"
            The smirk on her lips lingers. "Oh, you want to know?"
            
            I nod.
            
            She looks away too quickly, as if pretending to be bashful. "Of course I am," she says but in a tone that implies that there's a lot that she's not telling me. Then, she gives me a mischievous side-glance.
            
            "Why do you want to know, anyway?"
            
            "Just curious."
            
            "Hm."
        #"That's stupid."
            She gives me a little smile and a shake of her head. "It is what it is." 
        #Nod and remain silent.
            That checks out. Nothing less I expect from the Romans. Stupid demands, stupid customs.
            
            She nods.

Another moan disturbs the conversation.

"Can you imagine Gaius following me here?" She asks.

Absolutely not. Even if he knew she'd be here, I doubt he'd follow. Is that the reason she's here?

*goto ch5_camilla_why

*label ch5_camilla_why
"So, we're here because you don't want to be seen?"

"Yes. Also… I can make sure no one gets hurt."

"Hurt?" I realize she's talking about the couple next door.

Camilla shrugs. "Some men can be quite nasty towards prostitutes. I can use the element of surprise and—"

"Barge in and punch them?"

"Pretty much, yes." 

For some reason, that doesn't surprise me.

*fake_choice
    #"That's dangerous. You don't even have your bodyguards here."
        "I can manage. The brutes are usually naked, surprised, and vulnerable." She shrugs.
        
        "But—"
        
        "I appreciate the concern. I can manage," she repeats the words, this time with a little smile on her face.
        
        She's clearly telling that I should stay out of this hobby of hers.
    #"That's admirable."
        She shrugs. "Or maybe I want to blow off some steam and that's just my excuse."
        
        That sounds plausible, too. However, there's a part of me who thinks that she's not telling the truth right now. I think she actually cares.
        
        A weird thought. That she would care about the well-being of others.
    #Nod.
        She nods back at me.

"Why the singing?"

She purses her lip and sits on the stained bed. "Because I like it." She places her lute carefully beside her.

That makes sense, I suppose.

*page_break
I look at Camilla. She doesn't seem to mind the gaze, but she's not looking back at me, either. Something about her catches my attention. 

Then, I realize what I'm looking at. "I didn't realize you have briciní."

She turns to me with creased brows. "I have what now?"

"Ah." My Latin has failed me. "Fairies' kisses."

She tilts her head. 

"Uh, little stars. Freckles."

"Fairies' kisses? Little stars?" She muses to herself. She touches her face, as if remembering them herself. Then, she slightly shakes her head with her hand still resting on her face.

"I usually cover them with makeup."

"Why?"

"It is what's expected." The words are curt, as always.

*fake_choice
    #"I think your freckles look beautiful." I'm being truthful.
        *set manipulative -1
        *set camilla_friendship +1        
        She cocks her head and inspects me. I could swear that the smallest of smiles tugs at the corner of her mouth, but it's gone as quickly as it appeared. It's as if it was never there.
        
        Silence hangs between us peacefully before she says: "Thank you." The smile still rings through her words. 
    #"I think they look beautiful." I'm just saying it because I think she would like me to say it.
        *set manipulative +1
        She tilts her head at me, clearly suspecting my words. Then, she shrugs.
    #Remain silent.

*choice
    #I almost touch my own freckles in thought, mirroring her gesture.
        *set freckles true
        *goto ch5_camilla_freckles
    #I almost touch the scar on my face in thought, mirroring her gesture.
        *set scar true
        *goto ch5_camilla_scar
    #Remain silent.
        *goto ch5_camilla_look

*label ch5_camilla_scar
*set scar true 
She tilts her head as she looks at me. She even stands up to see my face more clearly. "I didn't realize you have a scar on your face."

"Where did you get those?" She points at the multiple horizontal scars on my cheek.

"A bear," I say, instinctively touching the skin where the mighty bear mangled my flesh.
        
A flash of amazement paints her gaze. "You fought a bear?" She whispers, clearly almost not believing my words. But the proof is on my face.
        
"She protected her cubs. I was in the wrong place at the wrong time."
        
"What happened to the mother bear?"
        
I lied down to play dead. Eventually, she left me alone. Is that something I would like to tell her?

*fake_choice
    #Embellish the truth to make me look more courageous.
        *set manipulative +1
        "I punched her in the face."
                
        "You what?" Her eyes widen.
                
        "Nose is their weakest point. I knew what to do." Father always told me to punch and kick the bears in their faces. Then, he laughed and said that in reality I should play dead and pray to the Twins.
                
        "Then what happened?"
                
        "She left me alone."
        
        Her mouth is slightly open as she looks at the scar. She's clearly impressed.
        
        Ha! She bought the lie.
    #Tell the truth.
        *set manipulative -1
        "I, uh. Played dead."
        
        She gives me a slow, almost unimpressed nod. "You played dead and she left?"
        
        "Yes."
        
        "That's sensible."
        
        It is.
    #I'd rather not tell.
        I shake my head.
        
        "You're not going to tell me?"
        
        "No."
        
        "I see." Still, she looks impressed by the story.
*page_break
*goto ch5_camilla_look

*label ch5_camilla_freckles
I fight against the urge to brush my skin, now conscious about my own freckles.
        
She tilts her head as she looks at me. "I didn't realize you have little fairies' kisses, too." A little smile rings through her words. "I didn't realize before…"
        
"Realize what?" I ask, wholly unsure what to expect from her.
        
"How cute they look."
        
"Cute?"
        
Her lips burst into a smile as she shifts her gaze to meet mine. "A fierce barbarian with cute little briciní."

*fake_choice
    #Heat rushes to my cheeks and I look away.
        "Look at me," she commands. It's a playful order but still I find myself turning my gaze back to her.
        
        Her lips are slightly open as she looks at me. 
    #"You are a cute little noblewoman with cute little briciní."
        She lets out a snort of a laughter. "That I am."
    #"Cute? Really?" I don't know how to feel about that.
        I suppose I should be a little offended but the expression she wears is something I've never seen on her. There's a playful glint in her eyes. 
        
        "You are. You'll just have to admit it." Her voice is commanding. 
    #Nod. I suppose that's what I am.
        She lets out a little snort of a laughter. "A serious little barbarian with cute little briciní."
        
        She's being unusually playful.
    #"Uh-huh. Sure."
        She raises a brow at me.
        
The smile on her dies as she starts to scrutinize my face in thought.

*label ch5_camilla_look
*if freckles
    "How didn't I notice them before?" She muses to herself. Her gaze is tightly peered onto my freckles as she moves hand. I almost expect her to touch my face. 
    
*if not(freckles)
    Her expressionless face examines me intensely.
        
*fake_choice
    #Look away with my cheeks slightly heated. She makes me feel awkward.
        The fervor in her gaze forces me to look away. Heat still lingers on top of my cheekbones, making me implore of the Twins that it won't spread across the whole of my face. Why am I so easily flustered? 
        
        Then, something caresses the skin of my cheek, stopping any and all thoughts rummaging in my head.
        
        It takes a moment to realize it's her. To admit that it's her. And when I do, she's already taken a hold of my chin, making me look at her. The skin of her fingers is coarser than I thought; the power of her grip strong, even if her touch is delicate. 
        
        Do I want to? I'm not sure.
        
        Heat clouds her gaze. Her lips are slightly open, revealing the tip of her tongue. She wets her lips and says: "You're beautiful."
        
        Her words make me take a sharp, surprised breath.
        
        *fake_choice
            #"Thank you," I manage to whisper, almost wishing that she'd touch me.
                *set rude -1
                I'm not sure where. A part of me yearns for her touch. Still, I manage to keep my words almost steady. 
                
                Once the words leave me, her gaze moves to my lips. Heat in her gaze darkens as she looks at them.
                
                My lips are hot and dry. I want to lick them but I can't move under her gaze.
                
                Her fingers touch my lips. Instinctively, I open my mouth slightly, almost to welcome her touch. 
                
                She accepts the invitation: her fingers penetrate my lips to feel the tip of my tongue. She caresses my lips, spreading my own saliva.
                
                "Your lips were dry," she whispers.
            #I turn even redder.
                My face is nothing but heat. Heartbeat pounds in my ears. I want to look away but I can't.
                
                I bite my lip to control the raging emotions. To have some semblance of control.
                
                She merely looks at me. Her face is painted with curiosity and delight, there's a little lopsided smile on her face when she says: "You're cute."
                
                "Cute?" I ask, my voice hoarser than I would prefer.
                
                She nods, caressing my chin with a little more pressure. "The mighty barbarian trembling under my touch." Words leave her like sweet poison.
            #Flee from her touch.
                I tear my control back from her by taking a step back.
                
                She tilts her head after me.
        
        A loud BAM makes me fly away from her. 
        
        Someone slammed a door next to our room.
    #Look at her as a challenge.
        A little smile dances across her lips as she responds to my declaration of war in kind.
        
        Then, clearly thinking that she has the upper hand, she takes a hold of my chin. The skin of her fingers is coarser than I thought; the power of her grip strong, even if her touch is delicate.
        
        The tip of her tongue wets her lips again as she says: "You're defiant."
        
        I give her a small smile. She must like it. The smile still lingering on her lips tells me so.
        
        *fake_choice
            #"Is that to your liking?"
                Darkness clouds her gaze as she says: "Perhaps."
                
                She gives me a lopsided smile and caresses my chin with a little more pressure, all the while looking at me, waiting for a reaction.
            #Grab her arm.
                In one quick movement, I take a hold of her arm. 
                
                She gasps and shoot me a glare. "You dirty barbarian, give me my arm back." Her breathy insults caress my skin.
                
                "You'll have it back when I deem you worthy of your hand," I say, leaning to her, looking at her.
                
                She squints her eyes, her breathing quickening. "I will—"
                
        A loud BAM makes me fly away from her. 
        
        Someone slammed a door next to our room.
    #"Is there something nasty in my face?" Her gaze is making me feel extremely awkward.
        I want her to look away and I resort to my defense mechanism: humor.
        
        She blinks, as if waking up from a daze. "Oh. No. I'm sorry."
        
        Hearing her apologize so quickly, and without a trace of sneer in her tone is almost unnerving. 
        
        I shake my head. "It's alright."
        
        "I got lost in thought," she says.
        
        "What thoughts?"
        
        "How you're so far from home." She remains silent for a moment or two, and just as I'm about to ask, she says: "I'm sorry for what happened to you."
        
        A loud BAM makes me almost jump. Someone slammed a door next to our room.
    #Remain silent and wait for her to be done with the inspection.
        *set disciplined +1
        I merely wait for her to be done with whatever she's doing. I'm not sure what her game is. Is she trying to make me feel awkward?
        
        Possibly.
        
        Finally, she blinks, as if waking up from a daze. 
        
        "Oh. I was just thinking."
        
        "About what?"
        
        "How you're so far from home." She remains silent for a moment or two, and just as I'm about to ask, she says: "I'm sorry for what happened to you."
        
        A loud BAM makes me almost jump. Someone slammed a door next to our room.
    #"What is it?"
        She blinks, as if waking up from a daze. "Oh. I was just thinking."
        
        "About what?"
        
        "How you're so far from home." She remains silent for a moment or two, and just as I'm about to ask, she says: "I'm sorry for what happened to you."
        
        A loud BAM makes me almost jump. Someone slammed a door next to our room.

With a frown on her face, Camilla looks at the direction where the sound came from. Then, she says: "I think we should leave."
*page_break
In the end, Camilla didn't let me escort her back to the barracks. She still had things to do, she said.

I had half a mind to follow her, to see what she's planning, but decided against it. It's already late. I leave for the barracks alone.
*page_break
*set ch5_met_someone true
*goto ch5_met_someone

*label ch5_date_niall
Marcus told me that Niall is heading for a shopping trip of his, and I should try to find him in a clothing store.

I wander about for a few moments before catching a glimpse of the red giant.

Niall's wide back disappears into a building. There's a neatly decorated sign saying that it sells textiles and clothing. It's of a nicer establishment, not one of those that sell all shades of browns as their tunic selection.

The door opens without a sound and I follow him in. 

The air is filled with incense. Rays of sunshine penetrate the small, multi-colored windows, making light and color dance in the air with the little trails of incense smoke. Sounds of labor come from another part of the building, probably people working on the said textiles.

There's a woman with Niall. She doesn't notice me, her eyes are captured by him.

She gives him a dreamy smile, her gaze devouring all of him. "My Lord, I'm so happy you could come by yourself. I would be more than happy to make business with your good servant but it's always a pleasure to see you."

"Hello there, Victoria. I felt like stretching my legs today. You're looking radiant as ever," Niall's voice wears a confident smile, something unlike him.

The woman, Victoria, giggles at the compliment and starts twirling her long hair around her index finger. "My Lord always knows how to make a woman's day brighter."

Niall hums to himself.

*fake_choice
    #I pout my lips. What on earth was that stupid hum? Why am I annoyed?
        *set niall_jelly true
        A part of my wants to step up and smack him on the back of his head. 
        
        Are they flirting? What is this? Also, why am I increasingly annoyed?
        
        That part of me who didn't want to smack his head, now wonders what the reason is for the anger. The smacker part is still fuming.
        
        The woman continues: "Did you like the tunic I sent you the other day, my Lord?"

        "Of course, I loved it! It was top quality, as always."

        "I figured that shade of blue would fit you, my Lord," she purrs.
        
        I can't take this purring and humming anymore. I clear my throat.
    #Ignore their banter and wait for a good time to announce myself.
        There is some talk about some tunic, how fitting it was, nothing overly interesting. Finally, when there's a moment of silence, I clear my throat.
    #I can understand her reaction. Niall is impressive to look at.
        Erm. [i]I[/i] don't think that, of course. Others might think he is.

Both of them turn to me. Victoria wears a polite smile meant for customers, it's slightly colder than she aims at Niall. Niall, however, looks at me with delight illuminating his features.

"Hati! What a nice surprise!"

Despite the cold weather, it seems that he's still refused to put on trousers. His muscular shins and parts of his thighs are wholly exposed. He wears a purple cloak with gold trimming. What's more striking than that, however, is the lion fur over his cloak.

Striking, as in pompous. 

He takes a long stride towards me, clearly intending to hug me. What's even worse than that, his lips are pursed together.

He's going to greet-kiss me.

*fake_choice
    #Dodge the hug!
        I dodge his erected arms and barely manage to slip out of his grasp.
        
        He laughs. "Is this a game?" He tries to grab me again.
        
        "No! It's not!" I shout as I dodge him again. "Begone, beast!"
        
        Victoria starts laughing, too. They laugh while I'm in peril.
        
        Finally, Niall stops chasing me. He smiles, as if this is funny.
    #"I don't want to be hugged."
        He stops on his tracks. "Oh, right. I'm sorry. It's a habit."
        
        You can take your habits away from me, thank you very much.
    #"Stay away from me!"
        I shout at him to keep his distance. He stops on his tracks with his brows raised.
        
        "I'm, uh, sorry," he mutters.
        
        Victoria looks at us with her brows slightly raised.
    #I surrender to my fate and remain in place.
        It is what it is, for whatever reason I find myself surrendering to my fate. It's easier that to fight it.
        
        Yes. That's why I'm buried into Niall's arms right now; why his earthy scent surrounds me. He's been using rosemary and thyme for his hair. It's an oddly pleasant smell. I almost feel my shoulders relaxing.
        
        Then, he kisses me. It's a quick kiss, his beard has barely enough time to tickle my chin. I've seen highborn Roman men kissing each other like this. However, the act still manages to trap the air in my throat.
        
        Niall retreats, his face a little flushed, as if just realizing what he did.
    #I sigh and erect my arms, preparing myself for what's to come.
        It's what you're supposed to do when meeting someone, right? I need to act like normal people.
        
        Yes. That's why I'm buried into Niall's arms right now; why his earthy scent surrounds me. He's been using rosemary and thyme for his hair. It's an oddly pleasant smell. I almost feel my shoulders relaxing.
        
        Then, he kisses me. It's a quick kiss, his beard has barely enough time to tickle my chin. I've seen highborn Roman men kissing each other like this. However, the act still manages to trap the air in my throat.
        
        Niall retreats, his face a little flushed, as if just realizing what he did.

"What are you doing here?" Niall asks.

"Buying clothes, of course." I don't know why it's difficult to say that I was here looking for him. He might take the wrong idea. He might think that I don't mind his company [i]that[/i] much.

Niall's cheeks redden a little as he shakes his head. "Of course! This is a clothes store."

I give him a nod. It is, indeed.

"Uh, that was probably a little stupid to say."

I let him stew in his embarrassment for a while. He wasn't wrong, per se.

*page_break
"Well, since you're here to buy clothes…" 
*if clothes = "cheap" 
    He eyes at my tunic with little holes in it.
    
    "Um." His expression oozes pain and suffering. Because of my clothes?
    
    *if hobby_fashion
        Well, they are horrible but I'm a little defensive about the reaction. "They are not that bad…"
    *if not(hobby_fashion)
        "The clothes are fine," I say in defense. They are fine. They serve their function, what else would I want.
    
    "How have I let you walk around like this," Niall mutters to himself, all but ignoring me.
    
    Before I can answer, he claps his hands: "Now! Victoria! Bring us a selection of your finest tunics."
    
    "Right away, my Lord!" Victoria scurries to another room.
    
    Niall gives me a nod. "We will handle this. Don't worry."
    
    *choice
        #Yes. Thank you. Give me new clothes!
            *set ch5_clothes_enthusiast true
            I give Niall an enthusiastic nod. I almost start clapping my hands with glee but manage to stop myself just in time. I'm not [i]that[/i] excited.
            
            I'm not excited at all, of course. I'm just slightly content.
            
            Yes, that'll do.
            
            Victoria arrives with another woman, their arms filled with different tunics in different shades of blues, reds, purples, even golds.
            
            Yes, please.
            *goto ch5_niall_clothes_gimme
        #Give him a stern shake of my head. I don't want any clothes.
            "But—"
            
            I shake my head firmly and cross my arms.
            *goto ch5_niall_clothes_no
        #"I like my clothes!" I'm not letting him buy me new ones.
            "You… you like them?" He takes a closer look at me. Then, he grimaces. "Hati, please. Let me buy you new clothes. Look at this! May I?"
            
            He points at one of the holes in my tunic. "May you wha—"
            
            He sticks his finger through the hole, poking me in my stomach. "I suppose this is a good way to ventilate your skin but—"
            
            "Hey!"
            
            "Oh, sorry!" He yanks his hand away from me. "But the case still stands. Your tunic is in horrible shape and I implore you: please let me buy you new ones."
            
            I purse my lips and cross my arms. "No."
            
            "But…"
            
            "No."
            *goto ch5_niall_clothes_no
        #"I like my clothes..." There's some hesitation in my voice.
            Sure, they're filled with holes. And the color reminds me of a mud on the streets. But—
            
            But what?
            *goto ch5_niall_hesitation
        #I'm not sure if I want him to buy me new clothes. I would be indebted to him.
            *goto ch5_niall_hesitation
        #"Won't I stand out?"
            "Stand out? Isn't that a good thing?"
            
            "Well, no." Not when you're on the run and constantly fearing for your life.
            
            "You won't stand out. There are men with rich relatives or… something."
            
            That doesn't sound too convincing. I purse my lips in thought.
            
            "Hati. If anything, people will think that you're a man of good tastes and you have friends in high places. They wouldn't say anything, I'm sure."
            
            I'm still unsure about that, however… I can always choose not to wear the tunic.
            
            "You can always tell me if anyone is harassing you."
            
            Would he actually do anything about it? He must know how the Optio treats us. I doubt I can trust him.
            *goto ch5_niall_hesitation

*if clothes = "fine"
    He looks me up and down before giving me an approving nod. "Your clothes are not bad."
    
    I start nodding—
    
    "But they could be better." He turns to Victoria: "Victoria! Bring us a selection of your finest tunics!"
    
    "Right away, my Lord!" Victoria scurries to another room.
    
    *choice
        #"No."
            I'm not going to try on any clothes.
            
            "Are you—" Niall starts asking.
            
            "Sure? Yes."
            *goto ch5_niall_clothes_no
        #Just go with it.
            I don't necessarily need new clothes but I won't start refusing gifts.
            *if hobby_fashion
                Besides, knowing Niall, the tunics will be of highest quality. How could I refuse?
                
            Victoria arrives with another woman, their arms filled with different tunics in different shades of blues, reds, purples, even golds.
            
            Yes, please.
            *goto ch5_niall_clothes_gimme
        #"I like my clothes..." There's some hesitation in my voice.
            Sure, they are not as nice as Niall's but… 
            *goto ch5_niall_hesitation
        #I'm not sure if I want him to buy me new clothes. I would be indebted to him.
            *goto ch5_niall_hesitation
        #Yes. Thank you. Give me new clothes!
            *set ch5_clothes_enthusiast true
            I give Niall an enthusiastic nod. I almost start clapping my hands with glee but manage to stop myself just in time.
            
            Victoria arrives with another woman, their arms filled with different tunics in different shades of blues, reds, purples, even golds.
            
            Yes, please.
            *goto ch5_niall_clothes_gimme

*label ch5_niall_clothes_no
Victoria arrives with another woman, their arms filled with different tunics in different shades of blues, reds, purples, even golds.

Niall turns to them with a sad smile. "I'm sorry for bothering you ladies. We decided that we don't need those tunics at this time."

Victoria nods, seemingly not minding that she brought all twenty of her tunics to display. "Please, don't worry, my Lord." 

The tunics are taken away.

Awkward silence falls between us. Then, Niall turns to me and ask: "Would you have felt uncomfortable with me buying you clothes?"

*fake_choice
    #"Yes. I don't want to be indebted to you."
        "You wouldn't have—"
        
        "I don't want clothes from you." He's starting to insist. I give him a frown.
        
        "Oh. I'm sorry. I just… yes. I'm sorry." He sighs and looks away.
    #"I just don't need clothes."
        *if clothes = "cheap"
            "Ugh." He lets out a little sound of disapproval mixed with disbelief as he takes another look of my torn clothes.
            
            "I don't," I declare with a steeled face.
            
            "Yes. Evidently you don't. I was confused."
            
            "Clearly."
        *if clothes = "fine"
            He nods. "I can see that. I just thought that more would be merrier! When it comes to clothes, that's my motto in life."
            
            "Well, it's not mine. These will do."
            
            "I see."
    #Shrug. I don't need to explain myself to him.
        I give him a curt shrug. I don't need to explain myself.
        
        He nods at my non-answer and gives me a small smile. "Sorry, I won't pry."

*goto ch5_niall_victoria
*comment uusi tunika
*label ch5_niall_hesitation
Father always said that I should pay my debts. How much do these tunics cost? A small fortune, most likely. What does he want in return?
            
"Why are you hesitating?"

"What would you want in return?"

He tilts his head. "In return? Nothing, of course!"

"Nothing?" Disbelief oozes from my words.

"I just want you to be clothed properly."

"But why?" Why would he clothe me? I squint my eyes.

Victoria arrives with another woman, their arms filled with different tunics in different shades of blues, reds, purples, even golds.

Niall gives me a small, pleading smile. "I just do. Please?"

*choice
    #"Fine."
        I sigh and give in. 
        
        He gives me a bright smile. "Excellent! Victoria, please, show us your wares."
        *goto ch5_niall_clothes_gimme
    #"No."
        "But…"
        
        "No."
        
        He gives me a small nod. "Of course. I won't force you."
        
        As if he could.
        
        Victoria and the woman take the clothes away.
        *goto ch5_niall_victoria

*label ch5_niall_clothes_gimme
*page_break
The tunics are laid on the ground on top of a large cloth, so they don't get stained. There are different trims, some in golden threads, some in silver, some in shades of copper.

"So? What do you think? Which one strikes your fancy?"

*if ch5_clothes_enthusiast
    Just in time, I stop myself from letting out a little giggle. There are so many! How could I decide?
    
*if not(ch5_clothes_enthusiast)
    The decision will be difficult. With my hand on my chin, I study the display. As I suspected, the quality is top-notch.
    *if not(hobby_fashion)
        Even I can see that, despite lacking any deeper knowledge of the topic.

Niall watches me with a wide smile on his face. "Victoria's clothes are the most impressive in this town. Even people from Augusta Treverorum arrive here for her wares." 

Victoria blushes. "Oh, please, my Lord. You're embarrassing me."

"It is but the truth." Then, Niall turns his attention back to me. He studies my features before giving me a little smile. "Could I pick one for you?"

*fake_choice
    #"I suppose..."
        *set niall_tunic true
        *set niall_trust +1
        The smile on his face brightens. "Thank you for trusting me with this."
        *goto ch5_niall_tunic_choose
    #"Sure." The thought makes me somewhat giddy, for some reason.
        *set niall_tunic true
        *set niall_trust +1
        I'm not sure why the thought of him choosing me a tunic makes me feel a bit light in my head. Have I caught a flu?
        
        Twins, I hope not.
        
        The smile on his face brightens. "Thank you for trusting me with this."
        
        I find myself smiling back at him.
        *goto ch5_niall_tunic_choose
    #"No, I will pick one myself."
        *goto ch5_tunic_choose_myself

*label ch5_tunic_choose_myself
I look at the tunics. There's an earthy green that draws my eye. On the other hand, there's also a golden-like beige.

*fake_choice
    #I want the shiny gold.
        *set clothes_flashy true
        I had my eye set on that golden tunic the moment I saw it. I can't wait to try it on.
    #The green would look nice on me.
        *set clothes_modest true
    #I'll have a basic white.
        It's difficult to find white tunics this bright. 

Niall nods. "Excellent choice."

I quickly add: "I think it will fit me without trying it on."

"Are you sure? The length—"

"I'm sure. It looks fine."

Niall nods and smiles. "I'm glad you like it."

So, now I have a new and shiny tunic in my bag.
*goto ch5_niall_victoria

*label ch5_niall_tunic_choose
Niall turns to the selection of tunics. He takes one off the ground, it's a shade of beige that almost shines like gold.

He holds the tunic in front of me, squinting his eyes. Then, he nods in approval.

"What do you think?" He asks.

*fake_choice
    #"It's too flashy for me."
        *set clothes_modest true
        "I see. I thought so." He smiles.
        
        He turns back to the tunics, this time picking up a moss green tunic. It doesn't have any trims on it but the quality is spectacular.
        
        "Yes. That will do," I say with a firm nod.
    #"I like it."
        *set clothes_flashy true
        I had my eye set on that golden tunic the moment I saw it. I can't wait to try it on.
    #Shrug. I don't know.
        Niall tilts his head. "It might be a bit too much," he mutters to himself.
        
        "How about this one?" He shows a basic white tunic. It's difficult to find a tunic that brightly white.
        
        I nod. "That will do."
        
Niall smiles. "Excellent."

I quickly add: "I think it will fit me without trying it on."

"Are you sure? The length—"

"I'm sure. It looks fine."

Niall nods and smiles. "I'm glad you like it."

So, now I have a new and shiny tunic in my bag.

*goto ch5_niall_victoria

*label ch5_niall_victoria
*page_break
Victoria turns to Niall with a tunic in her hands. "My Lord, it's your turn to try on a new tunic."

Niall rubs the back of his neck. "Ah, yes. I suppose."

He takes a brief look at me, clearly unsure how he should go on about this. Is he going to undress in front of me?

*fake_choice
    #Give him a wide grin and a nod. "By all means, Lord Tribune. Please bare your arse right here."
        His eyes widen at my words. "What?!"
        
        Muffled laughter can be heard from Victoria's direction. Niall is too flustered to look at her, he just stands there with his hands shielding his wide chest.
        
        "I… I would not bare my butt."
        
        "Oh?" I tilt my head. "Do you have your pants on?"
        
        "Of course! I'm not going about the town flashing my butt."
        
        "That's great. There are even fewer reasons to feel flustered about this."
        
        He pouts. "I'm not flustered…"
    #Give him a curt nod.
        I'm not opposed to it but it looks to me that he's not into the idea. He looks, in fact, quite horrified. He looks everywhere else but my direction. The smudge of mud on the floor, the discolored spot on the ceiling…
        
        He doesn't catch my nod.
    #"I'm not going to look."
        "It's not that you shouldn't. I mean… You don't have to look, if you don't want to. I mean it's not that I don't want you to look but— What? No, that sounded wrong. What I mean is that—"
        
        He babbles for a while. Victoria lowers the tunic in her hands, looks at Niall with slightly creased brows, then turns her gaze to me. 
    #Remain silent.
        I doubt he would undress in front of me. He looks horrified by the thought. He looks everywhere else but my direction. The smudge of mud on the floor, the discolored spot on the ceiling…

*page_break
Victoria asks: "Do you want to help my Lord to put on the tunic?" She gives me a little smile. It's difficult to decipher its meaning. The smile looks almost devious.

*choice
    #"Sure!" This is a good opportunity to make him even more flustered.
        The thought of making him suffer even more makes me smile. There's something delightful about the thought of teasing that mountain of a man. This is borderline bullying but I don't mind.
        
        Victoria's smile deepens as she hands me the tunic.
        
        "Hey, wait a moment—" Niall starts.
        
        Victoria shakes her head and says: "My Lord, please don't fret. Your friend is willing and ready to help you."
        
        "But— Ugh. Fine." He yields. Quite easily, I would say. Because he's used to obeying others, or is there something else?
        *goto ch5_niall_bold_tunic
    #"Umm, sure." I'm not sure if it's a good idea but I'll go with it.
        This is borderline bullying. However, I find myself agreeing with Victoria.
        
        Niall sighs in defeat, his shoulders sagging. "But I thought that—"
        
        Victoria smiles at him and says: "My Lord, you don't have to think! Your friend is ready and willing." She turns to me with the tunic in her hands. "Please, you know what to do."
        
        I suppose I do.
        *goto ch5_niall_awkward_tunic
    #"No, thank you."
        *set rude -1
        Niall sighs in relief. "Oh, thank Proserpina."
        
        Victoria gives me a little smile and helps Niall into his tunic with the level of professionalism that tells me that she's been doing this for years. I don't peek, Niall looks like he would spontaneously combust if I were to do so.
        
        "All done, my Lord."
        *goto ch5_niall_tunic_look
    #Shake my head. No.
        *set rude +1
        Niall sighs in relief. "Oh, thank Proserpina."
        
        Victoria gives me a little smile and helps Niall into his tunic with the level of professionalism that tells me that she's been doing this for years. I don't peek, Niall looks like he would spontaneously combust if I were to do so.
        
        "All done, my Lord."
        *goto ch5_niall_tunic_look

*label ch5_niall_awkward_tunic
I take a step towards Niall, who steels his features as he readies himself for my arrival. Oh dear. I don't know why I told Victoria that I would do this.

"Umm. I think we should take your tunic off, first." My voice is a little shaky. 

"Yes. That would be the most sensible way to go about it." His voice is even more shaky. His lips form a tight line as he gives me a little nod, his gaze not meeting with mine. He takes a deep, shaky breath and quickly slips off his tunic.

"Wasn't I supposed to—"

"Sorry, I got ahead of myself," he mutters to himself, now completely naked in front of me. Save for a skimpy underwear.

*fake_choice
    #Take a good look while helping him.
        I can't help it; my gaze is captured by his powerful frame. I don't think I've ever seen a man as buffed as he is. His physique is of a Celtic warrior. But there's something missing that a true warrior would wear: there are no scars on him. His skin is perfect. Only a few little moles litter his otherwise flawlessly pale frame.
        
        Niall shifts uncomfortably, thus making his muscles look even more prominent. Light from the braziers make shadows dance on him as he shrinks to himself. 
        
        Victoria clears her throat and looks at the tunic in my hands.
        
        Oh, right. I was supposed to help him with the tunic.
        
        "I, uh, here," I say and take a step towards him.
        
        I can hear him inhale sharply as I move closer. The sound makes me bite my dry lip. I'm so close to him that I can smell every nuance of his perfume, every hint of heather and rosemary.

        "Thank you," he whispers.
        
        "Um, can you put it on yourself?" I mutter, give up, and almost shove him the tunic. For some reason, my breath is trapped into my throat.
        
        He sighs in relief. "Oh, yes, thank you." He quickly slips into the tunic, quicker than I thought possible.
        
        "Alright, I'm ready," he says and looks away, his face still completely flushed.
    #Help him while trying not to look (and fail).
        I clear my throat and try to look away. But as if by magic, my gaze wanders back to his frame. I can't help it; my gaze is captured by his powerful frame. I don't think I've ever seen a man as buffed as he is. His physique is of a Celtic warrior. But there's something missing that a true warrior would wear: there are no scars on him. His skin is perfect. Only a few little moles litter his otherwise flawlessly pale frame.
        
        Niall shifts uncomfortably, thus making his muscles look even more prominent. Light from the braziers make shadows dance on him as he shrinks to himself. 
        
        Victoria clears her throat and looks at the tunic in my hands.
        
        Oh, right. I was supposed to help him with the tunic.
        
        "I, uh, here," I say and take a step towards him.
        
        I can hear him inhale sharply as I move closer. The sound makes me bite my dry lip. I'm so close to him that I can smell every nuance of his perfume, every hint of heather and rosemary.

        "Thank you," he whispers.
        
        "Um, can you put it on yourself?" I mutter, give up, and almost shove him the tunic. For some reason, my breath is trapped into my throat.
        
        He sighs in relief. "Oh, yes, thank you." He quickly slips into the tunic, quicker than I thought possible.
        
        "Alright, I'm ready," he says and looks away, his face still completely flushed.
    #Look away and try to help him without looking.
        I can't look at him, so I need to help him without the help of my sight. I start shoving the tunic in his general direction. 
        
        "What are you—"
        
        My finger sinks into something soft.
        
        "Agh! My eye!" 
        
        Oh, that explains.
        
        "Um, sorry about that," I mutter, give up, and give him the tunic. He sighs in relief and quickly slips into the tunic.
        
        "Alright, I'm ready."
*goto ch5_niall_tunic_look
        
*label ch5_niall_bold_tunic
I take a step towards Niall, who steels his features as he readies himself for my arrival. 

"Niall, you don't have to be so stiff. I'm not going to eat you." I'm just going to poke some fun out of you. Nothing serious.

His lips form a thin line as he nods. "I'm not stiff," he says all the while being extremely stiff. 

*fake_choice
    #"Tease him dominantly.
        "Lord Optio." I inch closer. "We are both men, right?"
        
        He bites his lip. "Well, yes. We are."

        "So? There's nothing to worry about." I give him a sweet smile. "Now, get undressed."
        
        Victoria cuts in: "My Lord, you're supposed to help him." A smile rings through her voice.
        
        "Oh, that's right." I just started ordering him around. A bad habit, I suppose. "Well, prepare yourself, my Lord." 
        
        I take a step towards Niall. I can hear the air trapping in his throat. The bulge in his throat moves in agony when he tries to swallow.
        
        I take another step. A tinge of delight runs through me as he shudders. It's a charming contrast: his body is that of a Celtic warrior, yet he trembles like a flame blown by the wind.
        
        I'm so close to him that I can smell every nuance of his perfume, every hint of heather and rosemary. I can feel his ragged, hot breath on my skin.
        
        "Are you quite alright, Lord Tribune?" I whisper.
        
        Just a little puff of air leaves his dry lips as an answer.
        
        I shake my head with a smile. It's been fun to tease him but I fear the veins in his temples might rip open. I quickly help him out of the tunic. He blinks, tries to shield himself, but I shake my head. I won't let my gaze linger any longer. Instead, I quickly help his head and arms through the holes of the new tunic, fasten his belt, and take a step back. 
        
        "All done."
                
        He looks at me, his head clearly still dizzy over what happened. "Um… Uh. I… Thank you."
                
        "You are quite welcome."
            *comment#Keep going.I smile. I'm not done just yet. "I take that as a yes. Now…" I lean to him and take a hold of the hem of his tunic. "First, we need to get this off."

    #Tease him light-heartedly.
        "Now now, Lord Tribune. Please calm your butt and let me help you."
        
        "My butt is incredibly calm, thank you very much. I just—"
        
        "Yes, yes," I cut him off, seeing that he's about to enter another tangent. I take a step towards him and I can hear the air trapping in his throat. That shut him up. 
        
        I take another step. The bulge in his throat moves in agony when he tries to swallow.
        
        Then, I'm so close to him that I can smell every nuance of his perfume, every hint of heather and rosemary. I can feel his ragged, hot breath on my skin.
        
        "Are you quite alright, Lord Tribune?" I whisper. I almost feel bad about this. 
        
        His face is pure anguish when he opens his mouth and tries to speak. Just a little puff of air leaves his dry lips as an answer.
        
        I smile and shake my head. It's been fun to tease him but I fear the veins in his temples might rip open. I quickly help him out of the tunic. He blinks, tries to shield himself, but I shake my head. I won't let my gaze linger any longer. Instead, I quickly help his head and arms through the holes of the new tunic, fasten his belt, and take a step back. 
        
        "All done."
                
        He looks at me, his head clearly still dizzy over what happened. "Um… Uh. I… Thank you."
                
        "You are quite welcome, my Lord."
    #Give him some privacy and let him dress by himself. I won't look.
        Enough teasing, I'm afraid that the veins in his temples might rip open. As I turn away, he sighs in clear relief.
        
        "Please let me know when you're ready," I say to him nonchalantly.
        
        Victoria looks at me with a questioning gaze but doesn't say anything. We wait in silence as Niall huffs and puffs himself into the tunic.
        
        "Alright, you can look."
        
*goto ch5_niall_tunic_look

*label ch5_niall_tunic_look
The tunic is short. It might be the shortest one he's worn. His powerfully curved calves are more prominent than ever. The purple hue compliments the shade of his hair. 

Niall eyes the tunic with some hesitation. "Isn't it a bit short?"

Victoria swats his worry away with a wave of her hand. "My Lord, that's the raging trend in Rome. Shorter the better."

"Oh?" He looks at the tunic again, weighing on its length. Then, as if the notion of something being fashionable makes up his mind, he smiles. "I suppose it's alright then."

I eye at the artisan. There's something fishy going on here.

Niall starts to change his clothes, this time urging us to stay back and let him to it by himself. He silently hums to himself.

*page_break
I turn to the Victoria and whisper: "Are short tunics really trendy in Rome?"

She gives me a small grin. "Yes. This short, however? Hmm. In some circles, perhaps."
        
What does that mean? Is she putting him in skimpy clothes on purpose?
        
*fake_choice
    #"Are you implying what I think you are?"
        She shrugs and looks away while stretching her arms. She looks guilty.
        
        "But… why?"
        
        "Why!" She whisper-exclaims. She sighs before apparently starting to imitate how strong Niall is, she puffs her arms and grunts for effect.
        
        "Ah. I see." She's purposely objectifying the man.
        
        "In my defense," she starts, "I'm not forcing anything. I'm just… poking him towards the right direction."
        
        "I see." I'm not sure if that justifies the action.
    #"Oh! You're sneaky."
        She starts giggling. "Please don't tell him. He really likes the idea that he's the forerunner in fashion in this little town."
        
        Niall hums in content, as if providing a confirmation to her words.
        
"In my defense," Victoria says, "soldiers do have short tunics. He just has the shortest ones."

"What are you two whispering about?"

"Well, now. I'm afraid we'll have to bid you farewell, my lady."
*page_break
We're back at the streets. Niall gives me a questioning gaze.

"Do you want to go somewhere?"

I shrug. I don't know that many places around here. Before we can decide on a place to go, however, someone's shout interrupts us:

"Lord Tribune!"

A woman walks in a brisk pace towards us, her gaze captured by Niall.

He gives an easy smile at the woman. "Ah, Lady Minerva."

Another one? How is he this popular with the women? 

"Did your back pain get better?" Niall asks her.

"Oh, it did! It did, thank you so much, Lord Tribune." She twirls her hair around her finger. "Could I possibly come to the barracks some other time? I have other issues. With my back." She chirps and looks away with a blush tinting her face.

Niall purses his lips before glancing at me. Before I can say anything, he turns back to the woman.

"Of course. My door is always open for you, my lady." The smile brightens his features easily when he looks at her.

The woman leaves, her step almost skipping.

*fake_choice
    #"My door is always open for you," I mimic his words mockingly.
        *set niall_jelly true
        He turns to me with his mouth a little open. "What? She needs medicine for her back."
        
        "Uh-huh." I don't know why I'm like this, why this whole situation annoys me so. I'm sure he does something else with that woman, other than offer her back remedies. Why does it bother me, though?
        
        It's definitely not because I like Niall and would wish that he'd talk to me like he talked to the woman.
        
        Of course not! It's because his stupid face irritates me.
        
        He stops walking and cocks his head at me. "Hati? What's wrong?" His confusion sounds genuine. 
        
        I'm not sure if I can blame him for his puzzlement. My feelings seem to puzzle me, too. 
        
        "How do you have time to be a doctor on top of your Tribune duties?" I ask, to try and steer the conversation away from my… whatever that was.
        
        "Uh, I just like herbs. I wouldn't call myself a doctor."
    #"Who was that?"
        "A patient of mine," he says. 
        
        "So, you're a doctor on top of Tribune duties?" That sounds like a lot of work.
        
        "Uh, I just like herbs. I wouldn't call myself a doctor."
        
        "You're just selling medicine?"
        
        "I'm not selling it. I just give it away."
        
        "For free? Why would you do that?"
    #Ignore whatever happened and continue walking.
    #I'm a little annoyed by this but I won't say anything.
        *set niall_jelly true
        I purse my lips and look at the woman strutting away.
        
        "What is it?" Niall asks, as oblivious as ever.
        
        I'm debating on whether or not to snap at him, but decide against it. It would be foolish. I'm not even sure why I would do that. 

"So tending to people is your hobby?" I ask and dodge a pile of poop on the road.

"Well, yes. Something like that."

"Lord Tribune!" Another chirp.

"Uh," Niall is starting to look a little awkward as another woman struts towards us.

"Lord Tribune. I just wanted to thank you for the ointment." She smiles at Niall while playing with a bracelet on her hand.

*fake_choice
    #I'm getting irritated. Why aren
    #"Sod off, we were having a conversation." I hiss at the woman.
        Both the woman and Niall look at me. Then, the woman looks at the ground and starts muttering something before fleeing the scene.
        
        "Hati," Niall says, disappointment coating his words.
        
        "What? We were having a conversation."
        
        He purses his lips. "I suppose. But you could say it more nicely."
        
        I merely scoff at the notion.
    #I'm starting to get very annoyed but I won't say anything.
        I clench my jaw and try no ignore the ever growing pit in my stomach.
        
        Why am I feeling this way? I'm not sure if that woman's presence is more annoying than deciphering the reason for my annoyance.
        
        Finally, she leaves.
    #Wait for them to be done with their conversation.
        It's nothing overly interesting. She's happy about her ointment, she needs more of it, Niall vows to give her as much ointment as she needs.
        
"Ah, shit!" Niall exclaims.

"What—" But I don't have to ask. All I need to do is to look down and see that he's stepped into a pile of bull dung. Or donkey. Who knows? The most important thing is that his shoe is now completely drenched in feces.

"My best shoes!" He moans and tries to wipe it on the road. "These were lion-skin."

I shake my head. Seeing a man clothed in the most expensive tunic in the whole town and moaning how his shoe is ruined… It irks me. Romans gave him these riches. "You would've never got these riches if you stayed in Hibernia."

"No," he says curtly. He looks away, still kicking his shoe in the air. "No, I wouldn't have."

I find it difficult to pinpoint what is it that annoys me so with him. Yes, he's betrayed his people Is it because he seems so at ease with what he has? Like he's too comfortable. Shouldn't he be hateful and bitter?

More like… like me.
    
"Why are you like this?" The question slips from me before I can think. I dodge a man and his two bulls.
    
"Like what?" He cocks his head as he combs his messy hair with his fingers.
    
Happy, I want to say. Cheerful. Shallow.
    
A frown pervades his features as he purses his lips. He seems to understand my implication. "Is it so bad?"

I'm not sure. No. I suppose happiness is not bad. But…

Niall quickly shakes his head, clearly sensing that the conversation is moving into something more serious. "Let's talk about something more cheery, alright? Besides, we're in the middle of the road…"

"Like what?"

"Like…" He waits for me to come up with a topic.

*choice
    #"About Victoria purposely dressing you in skimpy clothes?"
        "What?"
        
        "She is. She told me so."
        
        He looks at his tunic. "Are you telling me these aren't fashionable in Rome?"
        
        "I'm afraid not."
        
        He bites his lip, takes another look at his exposed thighs, then purses his lips. "I knew that, of course."
        
        "… You did?" He's a terrible liar. The tips of his ears are red and his gaze is downcast.
        
        "Yes." He collects himself and nods. "I just want to show off my thighs." He gestures at the said thighs. "I never skip a leg day."
        
        "I can see that."
        
        "Right?" He beams.
        *goto ch5_niall_questions
    #"About the girls you claim to be your customers?"
        *goto niall_ch5_customers_uh_huh
    #"Why do you fear the thought of being with a man?"
        His eyes widen and he looks around to see if there's someone listening in. "I…" He bites his lip before looking away with pain slightly distorting his features. "You should fear it, too."
        
        "Why?"
        
        "They will kill those who are caught."
        
        "One shouldn't get caught, then."
        
        He turns to me with a look that clearly asks if I've lost my mind. Then, he shakes his head. "I wouldn't want to endanger anyone's life like that."
        
        He looks serious about this. I suppose I should be serious about it, too. However, I must be numb to the constant peril by now.
        
        So, I merely shrug. That does explain things.
            
        Stupid Romans. Executing consenting adults for their love.
        
        Absolutely stupid.
        *goto ch5_niall_questions
    #I shrug. I don't have anything in mind.
        *goto ch5_niall_questions

*label niall_ch5_customers_uh_huh
His face flushes red. "They [i]are[/i] my customers."
        
"Oh, really? Just your customers?"
        
He opens his mouth but nothing comes out. Just a little sizzle of air.

"What was that?"
        
Another sizzle.

*fake_choice
    #"Are you having trouble with breathing?"
        He exhales deeply and shakes his head. "No, I just… Why?"
        
        "Why am I asking?"
        
        He nods.
        
        I suppose that's a good question. Why do I care about the women she meets?
        
        "I just am. So… you're not going to tell me?"
        
        "There's nothing to tell. Please, let's just…"
        
        I doubt he's telling me the whole truth. However, he looks like he's about to pass out. It could be an act, though. I'm not sure if I should test that theory.
        
        *if build = "heavy"
            Technically, I could carry him if he fainted.
        *if ((build = "average") or (build = "lithe")) 
            There's no way I could carry him. Better not risk it. 
        I could always leave him on the street, I'm sure someone would help him. 
        
        Or rob him. Either way.
    #"So, you're sleeping with them."
        He starts coughing loudly. Are his coughing fits a way for him to guide the conversation out of unpleasant topics? I wouldn't put it pass him.
        
        "So?" I ask, making him cough a little louder.
        
        I wait for him to collect himself. I have all the time in the world. I'm still unsure why I'm so keen on knowing this but… I've picked my battle. This is it.
        
        "I'm sorry, there was spit and—"
        
        "Yes. Now. You're sleeping with your customers?"
        
        He grimaces. "I… No?"

        "Why are you asking me?"
        
        "I'm not, sorry. I… no. I'm not currently sleeping with my customers."
        
        "Well, thank goodness you're not doing it currently, would be awkward to stand here."
        
        "No! I mean. Yes, it would be. I mean that I'm not sleeping with anyone at this point. I haven't slept with anyone for a while."
        
        "Uh-huh." I squint my eyes at him. I suppose that piece of information will do. It does make my heart feel a little lighter, for some reason.
        
        Again, though. Why am I asking? I frown at the thought.
    #Remain silent. He clearly doesn't want to talk about any of this.
        When I stop with the interrogation, he lets out a deep and grateful sigh. "Thank you. There's just nothing to tell about them. They are my customers. I… don't do anything with them."
        
        I nod. I'm not sure if I believe him.
        
        He adds something under his breath. It almost sounds like 'anymore' but I could be wrong.
        
        "What was that?" I ask. 
        
        "Oh, nothing."
*goto ch5_niall_questions

*label ch5_niall_questions

Niall lightly shoves me to the side as we dodge a carriage riding past us. 
*if niall_bath
    He turns to me with a reassuring smile. "Marcus mentioned that you'd like to use my bath."
    
    "Yes. I would like that." Isn't he going to ask why I need to use his bath?
    
    "Of course you can." No, apparently he isn't. "After what happened with the Optio…" 
*if not(niall_bath)
    "I heard what happened with the Optio."

He purses his lips and looks at me. "I'm so sorry you had to go through with that."

*if floyd_nooo
    "I didn't receive any punishment… It was Floyd who did."
        
    Niall's features darken. "Flogging?"
        
    I nod. 
        
    "Did he survive?"
        
    I nod.
        
    "I'm sorry." Pain smears his face. "I wouldn't wish that fate to anyone." Agony seeps into his words, implying that the subject is even more personal to him that he lets on. Then, he nods. "Marcus chose you."
        
    I sigh. He did. And I still don't know why. "Why?"
        
    He shrugs. "I don't know. I wish I could say it's for a good reason but it's Marcus we're talking about…" He mutters the last part more to himself than to me.
        
    "You don't know anything about his motives?"
        
    "When it comes to you? No."
    
    I tilt my head at him. He seems to be telling the truth.
    
    "Anyway," he sighs. "I will have to visit Floyd later. And have a stern conversation with your Optio."
    
*if not(floyd_nooo)
    "Him trying to rip my clothes off in front of everyone? Not the most pleasant experience, sure."
    
    Niall sighs and rubs his face. "I never ever liked that creep." He shakes his head with disgust.
    
    "You didn't?"
    
    "No. Who would? His mother would probably. And Marcus seems to tolerate him, for whatever reason."
    
    "Why is it? Do you know?"
    
    "Zoilus is extremely ass-kissing, perhaps Marcus likes that."
    
    "Hm. Perhaps." That would make sense.

He steels his features. "He should be demoted for what he did."
    
"You think he will be?"
    
"It's for Marcus to decide."

"Couldn't you have a say in it, too?"

"I…" He looks at me. "Perhaps. I mean, yes. I could. Would it help you?"

"Yes."

"Then, I will try to help you with that." He nods and smiles.

Then, it's as if he sees something in my face. 
    
*choice
    #Is he looking at my freckles?
        *set freckles true
        *goto ch5_niall_freckles
    #Is he looking at the scar on my face?
        *set scar true
        *goto ch5_niall_scar
    #He just stares at me.
        *goto ch5_niall_stare

*label ch5_niall_stare
I'm not sure where to look.

*fake_choice
    #Aggressively stare back at him.
        I squint my eyes and prepares myself for counter-attack. Let's see who's staring who.
        
        He's tenacious. He's not giving up and neither am I.
        
        After a little while, he starts blinking furiously. "Oh, my gods! So sorry. I was lost in thought."
        
        "That's it?" I ask, still squinting.
        
        "Well, yes. I'm, uh… Why are you looking at me like that?"
    #Why is he staring at me? It's making me uncomfortable.
        I try to look away, to make him realize that he's staring at me and it's not wanted. But, he doesn't get the message. When I turn to look at him, he's still staring at me.
        
        "Um, what?" Heat starts creeping onto my cheeks. 
        
        He starts blinking furiously. "Oh! I'm sorry! I was lost in thought."
    #Remain silent and wait for him to be done with the staring.
        He keeps looking at me for a while. Finally, he seems to wake up. He blinks at me and quickly looks away.
        
        "Erm, sorry. I was lost in thought."

*goto ch5_niall_goodbye

*label ch5_niall_freckles
"You have briciní," he says. "Little stars." 

My hand wanders to my face. 
    
*fake_choice
    #"I do. What about it?"
        "I, uh." He bites his lip and frowns. "I just haven't realized it before."
        
        "They are quite prominent, how have you not seen them before?"
        
        "Um. I'm not sure." He shrinks to himself and looks away.
    #Why is he staring at me? It's making me uncomfortable.
        I try to look away, to make him realize that he's staring at me and it's not wanted. But, he doesn't get the message. When I turn to look at him, he's still staring at me.
        
        "Um, what?" Heat starts creeping onto my cheeks. 
        
        He starts blinking furiously. "Oh! I'm sorry! I was lost in thought."
    #"Oh, you mean fairies' kisses?"
        He chuckles. "That's what you call them? That's cute." With a warm smile he inspects every single freckle on my face. "To think that little fairies would kiss you this many times."
        
        "It's kind of cute, yes."
    #Remain silent.
        He keeps looking at me for a while. Finally, he seems to wake up. He blinks at me and quickly looks away.
        
        "Erm, sorry. I was lost in thought."
*goto ch5_niall_goodbye

*label ch5_niall_scar
He points at the multiple horizontal scars on my cheek. "I've been meaning to ask… Where did you get those?"

"A bear," I say, instinctively touching the skin where the mighty bear mangled my flesh. "She was protecting her cubs."

"You fought a mother bear?" His eyes widen.

Well, not exactly. I lied down to play dead. Eventually, she left me alone. Is that something I would like to tell him?

*fake_choice
    #Embellish the truth to make me look more courageous.
        *set manipulative +1
        "Indeed. I punched her in the face."
                
        "You what?" His eyes widen even more.
                
        "Nose is their weakest point. I knew what to do." Father always told me to punch and kick the bears in their faces. Then, he laughed and said that in reality I should play dead and pray to the Twins.
                
        "Then what happened?"
                
        "She recognized the threat and left me alone." I puff my chest but act like it was not a big deal. Just a regular day for us Picts.
        
        His mouth is slightly open as he looks at the scar. He's clearly impressed. 
        
        Ha! He bought the lie.
        
        However, soon he asks: "Why didn't you just play dead?"
        
        "I, um, I felt like fighting."
        
        His eyes widen a bit. "I see."
    #Tell the truth.
        *set manipulative -1
        "I, uh. Played dead."
        
        He gives me an understanding nod. "Of course. That's the sensible thing to do. I would've done the same."
        
        I'm not sure if that makes me feel better.
    #I'd rather not tell.
        I shake my head.
        
        "No?"
        
        "No."
        
        "I see." He looks at the scars with increased curiosity. The truth is left unclear and his imagination can fill in the blanks. He looks like he's already woven a mighty story about how I fought off multiple bears with my bare hands.
        
Still he keeps looking at my face. The inspection is starting to make me self-aware.

"Is there something more?"

He blinks. "Oh! No. No no. No no no."

Alright, then.
*goto ch5_niall_goodbye

*label ch5_niall_goodbye
*page_break
Niall shakes his head. "I, uh. I think we should go. I have things to do." He looks like ready to bolt. I think we were supposed to be going somewhere but he looks like he changed his mind.

"Places to be?"

"Yes. Exactly."

What a coincidence. So do I. 

So, we part ways.
*page_break
*set ch5_met_someone true
*goto ch5_met_someone

*label ch5_date_quinn
There's no one to ask about Quinn's whereabouts. However, I don't need anyone's help to find ${q_him}.

For some reason I know where to find ${q_him}.

$!{q_he}'s in the town, I'm sure of it. It's as if I'm drawn to ${q_him}.

My feet lead me into the Forum and I wrinkle my nose at the noise. It's a wonder that ${q_he}'s here somewhere. $!{q_he}'d prefer the forest. What is so important that ${q_he}'d spend ${q_his} time here, instead?

Then, I catch a glimpse of ${q_his} ${q_hair} hair. $!{q_his} brown cloak slips out of my sight just when I almost reach ${q_him}.

"Quinn?" I ask after ${q_him}.

"Why are you following me?"

"Agh!" I shout and realize that Quinn has sneaked behind me. $!{q_he} looks at me with a little smirk on ${q_his} face, clearly content that ${q_he} managed to scare me.

"So?"

*fake_choice
    #"I wanted to spend time with you."
        *set manipulative -1
        "Oh? I'm flattered."
        
        $!{q_he} tilts ${q_his} head. "How did you find me?"
        
        "I just knew you'd be here."
        
        "Oh?" $!{q_he} looks surprised. This isn't part of whatever is happening between us? Why would ${q_he} look so surprised about it? 
        
        Then, ${q_he} shrugs. "I'm glad you did. There is something I've been meaning to show you."
    #"I was just passing through."
        *set manipulative +1
        "Liar."
        
        "Rude. I'm not."
        
        "Pfff. You're here to find me?"
        
        Before I can say, ${q_he} nods. "Good. There is something I've been meaning to show you."

$!{q_his} step is light as ${q_he} skips further into the marketplace.

"Where are you going?"

"To my favorite place in this awful town."

"That is?"

"You'll see!"

$!{q_he} gives me a wink and hurries back to me. $!{q_he} holds ${q_his} hand to me and smiles. "Take my hand."

*choice
    #I take it.
        *set quinn_trust +1
        $!{q_his} freezing fingers intertwine with mine. 
        
        $!{q_he} looks at our hands and gives me a wide smile. "Now, close your eyes."
        
        "Huh?"
        
        "I don't want you to see where we're going."
        
        I hesitate for a moment but finally close my eyes. 
        *goto ch5_quinn_trust
    #I refuse. I don't trust ${q_him} to escort me safely. And the very thought hurts.
        It's not that I don't want to trust ${q_him}. I do. But I can't. Not after everything that's happened. 
        
        I hide my hands behind my back and shake my head.
        
        Quinn gives me a small smile. "I understand that I'm asking a lot. However, you can't enter without closing your eyes. And you can't walk blindly without me holding your hand. So…" $!{q_he} offers ${q_his} hand again.

        "Why can't I enter without my eyes closed?"
        
        "I don't want you to know where we're going."
        
        "But…"
        
        "Please?"
        
        I sigh. "Fine." Despite me not trusting ${q_him}, I find myself obeying.
        *goto ch5_quinn_trust
    #I refuse. No way I'm holding ${q_his} hand.
        I quickly shake my head.
        
        "But you can't enter the—"
        
        "I'm not holding your hand."
        
        "Oh, fine. Be like that." $!{q_he} mutters something else under ${q_his} breath and grins. "You oaf."
        
        I purse my lips.
        *if ch3_quinn_demon
            "At least I'm not a demon oaf."
            
            $!{q_he} bursts out laughing. "A demon oaf? That's a new one." Not minding the insult and still chuckling, ${q_he} starts walking away.
        *goto ch5_quinn_nopetrust
    #I shake my head and remain silent.
        "No? Are you sure?"
        
        I still shake my head.
        
        "Oh. Fine. Be like that." $!{q_he} mutters something else under ${q_his} breath and grins. "You mute oaf."
        
        I give ${q_him} a pout. $!{q_he} chuckles and starts walking away.
        *goto ch5_quinn_nopetrust

*label ch5_quinn_nopetrust
Quinn leads me away from the forum and its noise. Before long, we arrive at the destination.

A bakery.
*goto ch5_bakery

*label ch5_quinn_trust
*page_break
The sounds of the forum enhance in volume when I lose my sight. The shouts of different sellers are more prominent, one of them keeps yelling how they need to sell all their fish before the night falls, just half the price.

Then, Quinn starts leading me away and the smells of the forum leave behind. There's still the smell of piss creeping around, the occasional pile of something vile that I step on (excrement, most likely).

*if clothes = "cheap"
    And the shit floods into my shoe through the hole in the bottom. I bite my lip and try to ignore the wet feeling on my foot.
    
    Just great.

"Whoops, sorry, didn't realize that was there," Quinn's voice is carefree and I'm not sure if ${q_he}'s actually sorry.

Finally, ${q_he} stops in ${q_his} tracks and exclaims: "Ta-dah!"

I take the blindfold off. I don't know what I expected to see but it wasn't this.

A bakery.
*goto ch5_bakery

*label ch5_bakery
"Quinn! What a nice surprise!" An older woman claps her floury hands while smiling like she's meeting with her grandchildren. With a slight limp but in a surprisingly quick step she approaches us. Then, without a warning, she takes Quinn into a bear hug.

"Agh!" Quinn yelps.

She's holding Quinn up with no problem at all, as if ${q_he}'s but a feather. How is a woman that feeble-looking that strong?

She squeezes Quinn another time. "Came for another round of cookies, huh?"

"Grandma! You're embarrassing me." Quinn looks at me with light pink gathering on ${q_his} cheeks.

"Ooh! You brought a friend." She lets go of Quinn when she notices me.

Oh no. Is she going to—

"Come here, you!"

She takes me into her arms, surrounding me in the scent of baked goods, honey, flour, nuts, cheese… Before I can protest, she lets go of me and gives me a warm smile, revealing the absence of a a few teeth.

"Let me look at you," she says and takes a step back, inspecting me.

*if appearance_chosen
    *if handsome_gremlin
        "Oh! What a handsome lad we have. You're making grandma's heart flutter."
        
        "Wha—"
    *if pretty_gremlin
        "Oh." She takes a closer look at me. "Aren't you a pretty boy. Beautiful. I wish I could just take you into my pocket and keep you there."
        
        "Well, I—"
    *if rugged_gremlin
        "Ohh." She gives me an approving nod. "Very nice. A rugged kind of man. Mm-hmm. You're making grandma's heart flutter."
        
        "That was certainly not my—"        
*if not(appearance_chosen)
    "What a…"
    *fake_choice
        #"...handsome lad we have"
            *set handsome_gremlin true
            She gives me an approving nod. "You're making grandma's heart flutter."
        
            "Wha—"
        #"...pretty boy you are."
            *set pretty_gremlin true
            She takes a closer look at me with an approving smile. "What a beautiful lad. I wish I could just take you into my pocket and keep you there."
            
            "Well, I—"
        #"...a rugged man you are!"
            *set rugged_gremlin true
            "Very nice." She tilts her head so she can see me better. "Mm-hmm. You're making grandma's heart flutter."
        
            "That was certainly not my—"       
            
"HA! I'm only joking." She starts cackling as she hurries back to the counter. "So, what would you like?"

Quinn beckons me to follow ${q_him} to the counter, too. There are different cookies on display, but also different breads, and some cakes.

"How many cookies are there?"

Grandma smacks the table, almost making me jump. "How many? My boy, you will wake without your teeth once you're done with my cookies."

Is that a threat?

She starts slamming different cookies on the counter in a slightly intimidating manner, some cookies are coated, others are not. Some have dried fruit and berries, others nuts.

That's a lot of cookies.

*page_break
Quinn nods with a wide smile on ${q_his} face. "Impressive, huh?"

*if still_broken
    I shake my head. "No. I can't eat cookies." Mother wouldn't approve.
    
    Quinn purses ${q_his} lips. "This again? I thought that you'd—"
    
    "I'd what?"
    
    "Well… You are all grown up, your mother is not here, I just thought that…"
    
    I purse my lips and shake my head. "Are you saying that I'm childish?"
    
    "No. I'm saying you've been led to astray. You can eat cookies."
    
    "But…"
    
    "Trust me, alright?"
    
    *if quinn_nopetrust
        I don't trust ${q_him}. What if the Twins struck me down because of ${q_him}? I sensed their presence, I'm not taking any chances.
        
        $!{q_he} sighs at my doubt. "Why would gods care about cookies?"
        
        "Mother said—"
        
        $!{q_he} sighs. "What she said was stupid."
        
        Excuse me? "Mother wasn't stupid."
        
        "I'm not saying she was stupid. I'm saying what she said was stupid." $!{q_he} talks slowly, as if interacting with a child.
        
        I frown. "I'm not going to eat any cookies."
    *if not(quinn_nopetrust)
        I suppose I could trust ${q_him}.
        
        I nod. "Fine. Give me anything you like."
        
        $!{q_he} smiles widely. "You won't regret this."
    
*if not(still_broken)
    I give ${q_him} a stern nod. "Just give me all the cookies."
    
    Grandma cuts in: "Oh, dear. You're going to have your tummy aching if you eat all of these."
    
    "Well, not [i]all[/i] of them—"
    
    "I will give you so many cookies, ${name}." Quinn smiles.
    
    There's a part of me who's still afraid of being struck down by lighting.
    
    Is that silly? Perhaps. Still, I take the offered cookies. I didn't perish the last time, I won't perish now.
    
*page_break

With two bags filled with cookies we venture towards the forest. 

Sunlight pierces the thick woods. Winter is here. The air in the forest smells crisp and dead. The decay of the autumn has ended, snow will soon wrap everything in its freezing embrace.

I look at Quinn. $!{q_he} studies a cookie in ${q_his} hand. $!{q_he} always had a sweet-tooth; that much hasn't changed. But so much else has.

"Why don't you talk about how things used to be?" I ask. It's been on my mind. $!{q_he} seems consumed by the need for revenge, ${q_he} doesn't seem to have time for reminiscence.

Quinn purses ${q_his} lips before swatting the question away like it's a fly buzzing in ${q_his} ears. "That life is gone."

"But…"

$!{q_he} looks away, ${q_his} gaze unreadable. Has it always been so difficult to read ${q_him}?

No. It hasn't. It used to be that I knew everything you were thinking about. Now, I'm not so sure.

"Fine." $!{q_he} sighs before shifting ${q_his} gaze to me. $!{q_his} voice is monotone and clear when ${q_he} says: "Do you remember how I used to love you?"

"Huh?" I stop with my cookie half-way to my mouth.

"Love you." $!{q_he} looks me dead in my eyes. $!{q_his} expression is intense.

"You did?"

"I loved you with all my heart. Wasn't it evident?"

I blink and remember.

*page_break
[b][i]In the past[/i][/b]

"Quinn." Father's voice is unfamiliarly worried. I can hear it clearly through the cracks of the door. "You need to protect ${name}. The Romans are getting ever nearer."

The Romans. I frown at the words. Why does father sound so distressed? We can beat them. We beat them before. Why would this time be any different?

"I will," Quinn says. Hearing it makes me smile. Of course ${q_he}'d say it. 

"No. You need to promise me." Father's seriousness makes me uneasy. "If our clan ever had a chance to get back on our feet after the Romans… ${name} needs to survive. And you need to see to it."

Why would I be the one to do that? What about brother? He's the one who's going to lead our people after father.
*comment veljen nimi
"I will protect ${name} I promise." Quinn's voice is determined and serious, the same way ${q_he} always sounds. But this time ${q_his} words hold even more solemnity.

Silence falls and just as I'm about to leave, father asks:

"You love my child?"

"With all my heart."

My eyes widen at the confession I was not meant to hear.

"That's good."

Father! Why would he talk like that? A part of me wants to barge in and shout at him, to make him realize that we can beat them. That the despair is not needed. That we can—

But the shuffling behind the door makes me remember that this is something I wasn't supposed to hear.

*page_break
[i][b]Present day[/b][/i]

*choice
    #"You used to love me... What about now?" I think I love ${q_him}, too.
        *set quinn_love_confusion true
        Quinn's always loved me. And ${q_he}'s meant to protect me. Why did I remember just now?
        
        How can I forget that I love ${q_him}?
        
        Also, why is ${q_he} talking in past tense?
        
        $!{q_he} bites ${q_his} lips before giving me a smile. "Of course I still love you. You're all that I have."
        *goto ch5_quinn_confusion
    #"You've always been my dear friend."
        *comment variantti
        The smile on ${q_his} face brightens. "Thank you. I can say the same about you. You're my dearest friend and I love you with all my heart."
        
        I almost chuckle at the declaration. It's a bit much but nothing less I expect from ${q_him}.
        *goto ch5_quinn_questions
    #"I used to love you, too." Now, however, my feelings are more messy and confusing.
        *set quinn_past_love_confusion true
        Quinn's always loved me. And ${q_he}'s meant to protect me. Why did I remember just now? I think I loved ${q_him}, too. But something's happened.
        
        $!{q_he} nods. "You did. Whether it was romantic or platonic, you did love me. Now… now it's not so clear anymore."
        
        I shake my head. $!{q_he} knows it.
           
        $!{q_he} smiles. "I understand."
        
        "You do?"
        
        "Of course. Things have changed, whether we like it or not."
        *goto ch5_quinn_confusion
    #Remain silent.
        $!{q_he} doesn't wait for me to say anything. Instead, ${q_he} smiles and nods.
        *goto ch5_quinn_questions

*label ch5_quinn_confusion
I frown and hold my head. "There are things I don't remember about you. Why is that?"

Quinn tilts ${q_his} head. "What things?"

*if quinn_love_confusion
    "That I love you," I blurt out in my confusion.
    
    $!{q_he} smiles. "You do?"
    
    "Well, yes. I think so. I just remembered it and it's… strange." It's as if there was a piece missing in my brain. How could I forget something like that? What else have I forgotten?
    
    $!{q_he} frowns, seemingly when ${q_he} realizes the implications. "That's… I don't know. Maybe it's—"
    
    "The trauma? But I remember everybody else. I think." I start to doubt myself. 
    
    Quinn's hand squeezes my shoulder. "You remember that you have two younger siblings, one older, and your father and your mother?"
    
    I nod. It's relieving to hear ${q_him} say that I haven't lost it all. Just… ${q_him}. 
    
    Quinn nods with a frown. "I know this is scary. We can figure this out together. Alright?"
    
    $!{q_he} looks at me with a smile, those icy blue eyes anchoring me into this moment. I take a deep breath and give ${q_him} a nod. "We will."
    
    "Please let me know if there is anything I can do to help."
    
    How is this possible? But before ${q_he} can ask again if I'm alright, I nod. I can manage. It's better to talk about something else and ignore this for now.
    
*if quinn_past_love_confusion
    "That I used to love you."
    
    "You don't remember that?" $!{q_he} frowns.
    
    "Is that surprising?"
    
    $!{q_he} shakes ${q_his} head. "Do you remember the others? Your family?"
    
    "Yes. I think." I start to doubt myself. 
    
    Quinn's hand squeezes my shoulder. "You remember that you have two younger siblings, one older, and your father and your mother?"
    
    I nod. It's relieving to hear ${q_him} say that I haven't lost it all. Just… ${q_him}. "But when it comes to you… it's more foggy. Like there are pieces missing."
    
    $!{q_he} nods with a frown. "I'm not sure what that means. But we can figure it out together, alright?"
    
    I nod, despite my hesitation. 
    
    I can manage. It's better to talk about something else and ignore this for now.

I ignore the shudder creeping into my spine. 

Quinn takes another look at me, as if to make sure. I give ${q_him} another nod. Perhaps I'm just confused.
*goto ch5_quinn_questions

*page_break
*label ch5_quinn_questions
"You know… I think it's high time that we made use of the blessing to help you even more. I've been snooping around. Do you want to hear what secrets the others hide?"

"Oh?"

$!{q_he} gives me a devious smile.

"You've been reading their minds?"

"Of course. As much as I was able. It's not as easy as it sounds." $!{q_he} nods, waiting for me to ask.

Right. I want to hear a secret of…

*label ch5_secrets

*choice
    #Marcus.
        *set marcus_secret true
        *goto ch5_marcus_secret
    #Niall.
        *set niall_secret true
        *goto ch5_niall_secret
    #Camilla.
        *set camilla_secret true
        *goto ch5_camilla_secret
    #Tinsae.
        *set tinsae_secret true
        The smile on ${q_his} face freezes. "Her."

        The air between us seems chiller than before. 
        
        "She knows more than she lets on. And the knowledge she holds is dangerous for the both of us."
        
        "Why? I still don't understand."

        "I know. I'm vague and I'm sorry about that. There's nothing more to tell. She just…" $!{q_he} searches for the right words. "…[i]smells[/i] wrong."
        
        "Smells?"
        
        "She has a whiff of something that's…. out of this world."
        
        "I… see." That hardly explains anything.

        $!{q_he} sighs and looks away. "It's all I know. I don't want to talk about her anymore."
        
        "Would you like to ask about the others?"
        *goto ch5_secrets
    #You.
        *set quinn_secret true
        *goto quinn_secret 
    #The Legate.
        *set legate_secret true
        $!{q_he} smiles deviously. "Yes. The Legate. Poor, poor Legate is so sad."
        
        "He's lost his wife and his son. Most of his daughters loathe him. But he still has Niall. He pours all of his love on that oaf."
        
        "He's lost Marcus?"
        
        "Something happened between them. I'm not sure what. I saw blood and grief. So, so much blood. Shrieks. Blood. Crying. They've grown apart but the Legate refuses to admit that."
        
        "What about Camilla? Doesn't he still have her?"
        
        "$!{name}. Have you seen them together? I don't need to read anyone's mind to know that it's not a happy marriage. More on Camilla's part than his. But they also need each other. She more than he does. I wonder why he puts up with her?" 
        
        $!{q_he} looks away in thought. Then ,${q_he} shrugs. "Pity, probably."
        
        "Is there anyone else you'd like to know about?"
        *goto ch5_secrets
    #I've heard enough.
        *goto ch5_quinn_end_date

*label ch5_niall_secret
"Oh, the oaf." $!{q_he} scoffs. "He's in denial of every one of his feelings. He doesn't know that himself. In the end, his indecision will eat him alive."
        
"Eat him alive?"
        
$!{q_he} shrugs. "Figuratively."

"I figured as much."

$!{q_he} points ${q_his} tongue at me.

"What feelings is he in denial of?"

"Didn't you hear? Every one of them. There's not a single feeling he's being true to. He's fooling himself. He puts his hands on his ears and refuses to listen." Then, ${q_he} adds: "Oh, and the crocodile poop was a gift for him. That idiot loves the oaf."

"The poop? The one Marcus made me carry?"

"That's the one. He was so happy about it, too. He uses it on special occasions. He relaxes while wearing poop on his face."
        
"I… see."
        
"The poop—"
        
"Yes, thank you, I got the picture."

"Indeed. So, tell me…" $!{q_he} peers at me, ${q_his} eyes glimmering with curiosity underneath fair-weather clouds. "What do you think of the oaf?"

What do I think about him?

*fake_choice
    #"Not much." I'm telling the truth.
        *set manipulative -1
        "Oh?" $!{q_he} sounds almost disappointed.
        
        "Why?" I ask. "Why do you want to know?"
        
        "I'm not sure. I sense that he could be turned. He could be an ally."
        
        "Turned?"
        
        "Yes… He'd be a powerful ally, despite his buffoonery. Give it a thought."
    #"He's a big idiot." That's the truth. But there's something else...
        *set manipulative -1
        *set niall_friendship +1
        What? What else is there? The fact that for some reason my stomach feels weird when I see his idiotic face?
        
        That is indeed weird.
        
        I feel Quinn's gaze on me, inspecting my every movement. "He is. Is that all he is?"
        
        "What are you implying?"
        
        "That you're a terrible liar. You've taken an interest in him. Whether a friend or something more…" $!{q_he} gives me a little grin. 
        
        I'm ready to retort again, but ${q_he} continues: "That's good."
        
        "Huh?"
        
        "He could be a powerful ally if we managed to turn him."
        
        "Turn him?"
        
        "Give it time." There's a wicked smile on ${q_his} lips. "We'll see how things turn out."
    #"I don't care about him." Why do I feel like I'm lying?
        *set manipulative +1
        I quickly shake my head to banish the unwanted thoughts of doubt. I don't care about him. At all.
        
        Quinn gives me a smile. "Oh? Not at all?"
        
        "No."
        
        "I don't believe you."
        
        "I don't care. I'm telling the truth."
        
        "No, you're not. You're a terrible liar. You've taken an interest in him. Whether a friend or something more…" $!{q_he} gives me a little grin. 
        
        I'm ready to retort again, but ${q_he} continues: "That's good."
        
        "Huh?"
        
        "He could be a powerful ally if we managed to turn him."
        
        "Turn him?"
        
        "Give it time." There's a wicked smile on ${q_his} lips. "We'll see how things turn out."
        
"Well…" $!{q_he} starts changing the subject. "Is there anyone else you'd like to know about?"
    
*goto ch5_secrets

*label ch5_camilla_secret
"She's dangerous."
        
"How so?"
        
"She plans to use you. Be careful. Strike first."
        
*if camilla_bedroom
    I nod. This is nothing new. "Yes. Apparently, she wants me to kill the Emperor."
    
    "Ah, you already know. What do you think of that plan?"
    
    "It sounds ludicrous."
    
    "It does." $!{q_he} nods, running ${q_his } finger on ${q_his} chin. "However… I see an opportunity. You do, too, don't you?"
    *goto ch5_camilla_pawn
*if bedroom
    "Does it have something to do with the arrival of the Emperor?"
    
    $!{q_he} nods. "How did you know?"
    
    "She planted a letter in the Legate's room during dinner. There was information about the Emperor's arrival."
    
    "It makes sense. She plans to use you to kill him. There's deep hatred every time she thinks of that man."
    
    "And how on earth should I do that?"
    
    $!{q_he} shrugs. "That's something to consider, despite the fact that it sounds ludicrous. I see an opportunity to use this information against her."
    *goto ch5_camilla_pawn
*else
    "Do you know how?"
    
    "There were glimpses of something involving the Emperor. I suspect she wants you to kill him."
    
    "The Emperor? That's ludicrous!"
    
    "Yes." $!{q_he} nods.
    
    "How on earth would I do that? Kill the Emperor?"
    
    "How should I know." $!{q_he} shrugs. "She seems to have a plan, however. Her thoughts ooze hatred every time she thinks of him."
    
    That's… not something I was expecting.
    *goto ch5_camilla_pawn

*label ch5_camilla_pawn
*fake_choice
    #If she means to use me as her pawn, it's my chance to use this against her.
        *set manipulative +1
        Quinn nods. "Your eyes squint in delight. Are you thinking of taking an advantage of the situation?"
        
        "Yes."
        
        "Of course you are," ${q_he} says with an approving nod. "That's why you'll outlive them all."
        
        $!{q_he} looks almost… proud. The way ${q_he} puffs ${q_his} chest and beams at me.
    #I refuse to be used like a pawn.
        I frown at the thought. "I don't like the sound of this."
        
        Quinn shrugs. "Why not aim for the big man, right?"
        
        "That's… really not that easy."
        
        "No, I suppose it won't be. Also, I think the punishment for trying to kill the Emperor is a gruesome one. Romans can be quite imaginative when it comes to torture and death penalties."
        
        Of course they are. Stupid, brutal Romans.
    #I'm using her, she's using me. It's only fair.
        I shrug at the news. 
        
        "Nothing's changed?"
        
        "Not really. Besides, I'm using her. It's only fair that she's using me."
        
        "Ha! It is. You're like two snakes."
        
        "Rude." I pout. I'm not a snake.
        
        "True, true. You're more like a cute little worm."
        
        "Quinn, please."
        
        "Wiggling your cute little worm butt away."
        
        "Yes, I got the picture."
    #Why does it slightly hurt me to think that she's only using me?
        *set camilla_trust +1
        I frown at the thought. It's almost ridiculous; of course I knew that she's using me. Right from the start.
        
        Perhaps I wished that things would change. Perhaps.
        
        Quinn peers at me with a piercing gaze. "Do you love her?"
        
        I quickly shake me head. "Of course not." It's too early for that kind of talk.
        
        What? Of course I wouldn't love her in any circumstances.
        
        "Do you want her to love you?" $!{q_he} peers into my soul, a part of me thinks ${q_he} knows even when I don't.
        
        I shake my head.
            
"Oh!" $!{q_he} yelps, making me startle. "I just remembered! Camilla eats cheesecake as breakfast."

"Huh?"

"Yes. Sometimes a whole cheesecake."

"A whole cheesecake? Who does that?"

"Camilla, apparently. She's a stress-eater and she's most stressed during mornings. So, she eats a whole cheesecake."

So, assassin plans and cheesecakes. That's certainly… something.
        
Quinn nods in content. "Is there anyone else you'd like to know about?"
*goto ch5_secrets

*label ch5_marcus_secret
"Hmm. The idiot." $!{q_he} shakes ${q_his} head in disgust. "That disgusting thing loathes himself and wants to die. I think we should help him achieve that goal."
        
He loathes himself? Well, good. He should. However, it's slightly weird to hear that he's self-conscious about it.
        
Quinn nods. Then, ${q_he} yelps: "Oh, and he writes poetry and thinks he's pretty good at it."

*fake_choice
    #"Did you just say poetry?"
        "Indeed. I didn't get a good glimpse but from what I understood, it's the naughty kind."
        
        "Smutty poetry?!"
        
        "Yes." $!{q_he} grimaces. "Please don't ask for details, I'm already going to have nightmares about him."
    #I burst out laughing. "What?!"
        "I know. I've yet to read any of it but I think it's safe to assume that they stink."
        
        Still chuckling, I wipe a tear off my eye. "I wasn't expecting that."
        
        "You know the worst part?"
        
        "Oh no."
        
        "It's the naughty kind. Smutty poetry."
        
        I look at ${q_him}. I have no words. $!{q_he} has no words. Neither of us have any words.
        
        So, both of us remain silent for a while, trying not to picture what sort of naughty poetry Marcus has been writing so far. 
        
        We look at each other and shudder. It's better not to think about that.
    #"Uh-huh." I don't have words.
        I want to shake my head in disbelief but does anything surprise me about that man anymore?
        
        Quinn nods. "I didn't want to believe it either. It's… why? Why? Why would he curse the world to bear such burdens?"
        
        "I… For some reason I'm not surprised."
    #"That's sort of endearing."
        "What?" Quinn's brows shoot to ${q_his} forehead.
        
        "What?" What did I just say? "I mean… that he thinks he can write poetry. He can't, right? That's what's endearing about it." My words fail me. What am I even thinking? Quinn looks at me as if I've lost my mind.
        
        No. I haven't. I just misspoke.
        
        $!{q_he} waits for me to say something that doesn't sound like I find my father's murderer endearing.
        
        "I, uh. Hate that guy."
        
        "$!{name}."
        
        "Yes?"
        
        "Get a grip."
                
$!{q_he} shakes ${q_his} head with a frown. "I really don't like reading his mind. Please don't make me do it ever again." 

"Why?"

"Are you seriously asking me that? He's full of himself. I hate to hear his voice in my head."

Ah. Indeed.

"Is there anyone else you'd like to know about?"
*goto ch5_secrets

*label quinn_secret
$!{q_he} smiles brightly. "Me? I don't have any secrets."
        
"You're lying."
        
$!{q_he} chuckles. "I am." Then, ${q_he} purses ${q_his} lips, as if thinking. "I love you."
        
"You already said that. It's not a secret."
        
"Oh, right. Well, how about this: I'm going to die."
        
"…What?" $!{q_he} shares the information like it's nothing. It makes me think that I misheard.
        
But Quinn continues as if it's a non-issue. "The Twins showed me. It's got something to do with the blessing. My mortal body can't take the burden of it for too long, I'm slowly dying as we speak."

I just look at ${q_him}. My mouth is slightly open as I process ${q_his} words. 

$!{q_he} just nods and purses ${q_his} lips. Finally, ${q_he} looks away. "Hey, you're making me feel self-conscious."

"You're just… going to die? When?"
        
"Soon? I don't know." $!{q_he} shrugs. 
        
"Why are you so casual about this?" I frown.
        
"I've done this all for you and I wouldn't trade it for the world. Besides, I'm sure we'll have time."

*choice
    #I'm about to cry. I can't lose ${q_him}.
        *set quinn_trust +1
        Tears start to prickle my eyes. Why? Why would ${q_he} die, too?
        
        Quinn's features soften. "${name}. Please. It's not that bad."
        
        "How can you say that?"
        
        "I was ready for everything when I asked the gods for help. They usually demand blood. You know that."
        
        "I…" I do. But why does it have to be ${q_him}?
        
        "You could ask the Twins about it. They refuse to talk to me."
        
        "I will." They haven't talked to me in a long time, either. But I won't accept that Quinn has to die. 
        *goto ch5_quinn_die
    #Hearing this makes me uneasy. 
        "Really?" I ask, as if it would make the truth any different.
        
        "Yes," ${q_he} states.
        
        I look at ${q_him} in silence.
        
        "What?"
        
        "What? How are you this calm about dying?"
        
        "I was ready for everything when I asked the gods for help. They usually demand blood. You know that."
        
        "But…"
        
        "You could ask the Twins about it. They refuse to talk to me."
        
        "I will." They haven't talked to me in a long time, either. But I won't accept that Quinn has to die. 
        
        "Perhaps they are wrong?" There's a little smirk on ${q_his} face, a telltale that ${q_he} doesn't believe it.
        
        $!{q_he} knows ${q_he}'s going to die. $!{q_he}'s already accepted it.
        *goto ch5_quinn_die
    #"You don't care that you're going to die?" $!{q_his} calmness irritates me.
        "I care. But if it's for you, then it's fine."
        
        "But… What if we can do something to prevent it?"
        
        "That would be great, sure." $!{q_he} shrugs another time, as if ${q_his} life doesn't matter, making the frown on my face only deepen. "The Twins don't talk to me. Perhaps you could ask them."
        
        "I will." They haven't talked to me in a long time, either. But I refuse to accept that Quinn has to die. Still, I can't help but ask: "How are you so calm about this?"
        
        "$!{name}. What do you want me to do? Fall on my knees and cry? Wallow in self-pity?"
        
        "No, I just…"
        
        "It is what it is. Perhaps the Twins are wrong?" There's a little smirk on ${q_his} face, a telltale that ${q_he} doesn't believe it.
        
        $!{q_he} knows ${q_he}'s going to die. $!{q_he}'s already accepted it.
        *goto ch5_quinn_die
    #Nod. This doesn't move me as much as I thought.
        I merely give ${q_him} a nod. $!{q_he} doesn't look too bothered by my non-reaction. $!{q_he} just smiles and gives me a nod back.
        
        "Do you want to know about anyone else?"
        *goto ch5_secrets
        
*label ch5_quinn_die
*set quinn_dont_die true
"Look, I'm sorry that I told you. It just added to your stresses. I'm sorry."

*fake_choice
    #"I'm glad you told me but I'm really worried."
        "I know you are. That's understandable. I would be, too, if I learned that you were going to die. However… it's good that it's me. Instead of you."
        
        "Why?"
        
        "Because I love you. I don't want to see you die."
        
        "But I should have to see you die?"
        
        $!{q_he} shrugs as ${q_his} tongue peeks from the opening of ${q_his} lips. "Too late, I declare the rights to pass away before you."
       
        "This is not funny!"
        
        "Everything is a little funny in this world."
        
        I sigh.
    #"I don't want you to die."
        $!{q_he} smiles. The smile is warm, it's just the way ${q_he} used to look at me when I was being unreasonable in ${q_his} mind. When ${q_he} wanted to calm me.
        
        "I'm not being unreasonable, I—"
        
        "You're not. I understand. However, you must've known what would happen when we got to the Romans. Either one or both of us would die. It's just how it is."
        
        "But…"
    #I shake my head. This is too much. Why would ${q_he} die, too?
        I take a shaky breath and try to remain composed. Everyone close to me dies.
        
        This is starting to be too much.
        
        Starting to be? When has this not been too much?
    #Remain silent and frown.
        "You look like you're really thinking about this. You big old frowny-face."
        
        I sigh. "How can you find this funny, too?"
        
        "It's a little funny, though? Tragic. Life is one big tragicomedy if you put your mind to it."
        
        I give him another frown.
    
"Hey, listen to me." $!{q_he} takes a hold of my chin, making me look at ${q_him}. "I'm still here, aren't I? My flesh and bones are still here."

"Yes, but—"

$!{q_he} shakes ${q_his} head. "There's no but. I love you and I'm still here."

"How can you say that you love me and talk about dying?"

"But I'm dying for you. Because I love you. Those two facts are intertwined in such ways that it's impossible to separate them."

*choice
    #I wish ${q_he}'d kiss me.
        *set quinn_kiss_want true
        *set quinn_rejection true
        I look at ${q_his} lips, hoping I could feel them on my own. They look soft and inviting, the way they've looked for so many years. Instinctively, I close my eyes and wait for ${q_him} to kiss me.
        
        To realize that I want it.
        
        $!{q_he} lets go of my chin and I hold my breath.
        
        But there's nothing.
        
        I open my eyes and see him smiling at me, definitely knowing what I wanted. For some reason, ${q_he} doesn't want to give it to me. Instead, ${q_he} says:
        
        "$!{name}… I love you."
        
        I shake my head, banishing the thoughts of kissing ${q_him}. Does ${q_he} mean to say that ${q_he} loves me as a friend? And as nothing more?
        
        Why do I feel so rejected?
        
        $!{q_he} frowns, ${q_his} features seemingly genuinely puzzled. "What's wrong?"
        
        As if ${q_he} didn't know!
        *goto ch5_quinn_rejection
    #I just look at ${q_him}.
        And ${q_he} looks at me. $!{q_his} fingers on my chin feel light against my skin, like they could disappear at any moment.
        
        $!{q_he} caresses my skin, so lightly it almost tickles.
        
        Then, ${q_he} lets go of me. $!{q_he} does so gently but with determination. "Please don't dwell on it. Every one of us is here to die."
        
        That doesn't make me feel as good as ${q_he} apparently think it should.
        
        $!{q_he} smiles. "Want to hear more secrets?"
        *goto ch5_secrets
    #I shake my head. "Don't talk like that."
        $!{q_he} lets go of me and smiles. "I'm sorry. I'm being awfully gloomy. That's unlike me, right?"
        
        I'm not sure anymore. It both is and isn't.
        
        "Please don't dwell on it. Every one of us is here to die."
        
        That doesn't make me feel as good as ${q_he} apparently think it should.
                
        Then, ${q_he} smiles and says: "Want to hear more secrets?"
        *goto ch5_secrets
    #Kiss ${q_him}.
        *set quinn_kiss true
        *set quinn_rejection true
        I look at ${q_his} lips and act before I change my mind. I kiss ${q_him}. 
        
        $!{q_his} lips are pillowy against mine, ${q_his} hot breath caresses my skin. With my eyes closed I wait for ${q_him} to return the kiss, to taste ${q_him} better.
         
        However… ${q_he} doesn't. $!{q_he} just stands there, ${q_his} lips frozen in place.
        
        I quickly let go of ${q_him}. "I'm sorry," I blurt out.
        
        "No. Don't apologize. I've been wondering how your lips taste like." $!{q_he} tilts ${q_his} head and looks at my lips with a wistful smile on ${q_his} face.
        
        "What did they taste like?" I ask, despite a part of me wanting to crawl in a hole and die.
        
        "You." $!{q_he} smiles. "I'm glad I could experience it. I love you."
        
        $!{q_he} talks like that but doesn't want to kiss me back. Does ${q_he} just love me as a friend?
        *goto ch5_quinn_rejection
        
*label ch5_quinn_rejection
*page_break
"Are you alright?" $!{q_he} asks, ${q_his} face appearing genuinely puzzled as ${q_his} hand closes in on my cheek. I quickly move away, not ready to experience ${q_his} touch.
        
"I am." It's just my pride that's wounded. Why is ${q_he} acting like nothing of note happened? Is ${q_he} trying to protect my feelings?

*fake_choice
    #"Let's just change the subject."
        Quinn, still smiling, nods and readily changes the subject: "Want to hear more secrets?"
        
        I look away with a small frown.
    #"Why won't you kiss me? If you love me?"
        Quinn gives me the softest of any smiles ${q_he}'s ever given me. $!{q_he} brushes a strand of hair off my face. There's pain in ${q_his} face.
                
        "You'll lose me. I want you to live without that pain."
                
        "Everybody dies."
                
        "That's what I kept saying to you." $!{q_he} smiles. 
                
        I shake my head with a frown. "I refuse to accept that."
                
        "That makes me love you more." $!{q_his} expression is wistful as ${q_he} looks up at the clouds racing above. The color of ${q_his} eyes is the same as the sky. "I've accepted my fate."
                
        "But…"
                
        "$!{name}. Please. All I can do is to accept my fate. Please don't take it away from me."
                
        I purse my lips and shake my head again. I refuse. "I will ask the Twins."
                
        "I hope they'll answer."
                
        $!{q_he} doesn't look convinced they will.
        
        "Well… Do you want to hear more secrets? This was supposed to be fun." $!{q_he} chuckles.
    #Remain silent and slightly hurt.
        Quinn gives me the softest of any smile ${q_he}'s ever given me. $!{q_he} brushes a strand of hair off my face. There's pain in ${q_his} face.
                
        "You'll lose me. I want you to live without that pain."
                
        "Everybody dies."
                
        "That's what I kept saying to you." $!{q_he} smiles. 
                
        I shake my head with a frown. "I refuse to accept that."

        "I trust what I was told." $!{q_he} smiles, ${q_his} expression wistful as ${q_he} looks up at the clouds racing above. The color of ${q_his} eyes is the same as the sky. "I've accepted my fate."
                
        I bite my lip in silence. I'm not sure if I'll accept the news as easily as ${q_he} does. I'll try to contact the Twins.
                
        "Well… Do you want to hear more secrets? This was supposed to be fun." $!{q_he} chuckles.
*goto ch5_secrets

*label ch5_quinn_end_date
*if quinn_dont_die 
    Once the secrets have been shared and Quinn looks like ${q_he}'s ready to leave back to the town, I find myself worried. Why wouldn't I be?
    
    $!{q_he} told me ${q_he} was going to die. How could I let that slide without another word?
    
    Quinn sighs when I don't follow ${q_his} lead. "It's about me dying, right?" $!{q_he} says as if ${q_he} was expecting it.
    
    "I just…" If I asked how ${q_he}'s so calm about this, ${q_he}'d say that ${q_he}'s accepted ${q_his} fate. $!{q_he} already said as much. It's difficult to accept.
    
    "${name}. I know it's scary."
    
    *choice
        #"I find it unnatural that you're so calm about it."
            *set quinn_trust -1
            $!{q_he} frowns. "Unnatural?" $!{q_he} takes a step back. "What do you want from me?"
            
            "I—"
            
            "What should I do? Tell me. If you're an expert on feelings and how to express them, then please, I'm all ears."
            
            $!{q_his} outburst makes me bite my lip. I suppose ${q_he} has a point. 
            
            *if quinn_nopetrust
                With everything that's happened so far, this only adds to my doubts and distrust.
                
            Perhaps I'm just afraid that ${q_he}'s going to leave me.
            
            $!{q_his} features soften and ${q_his} posture relaxes. "I'm sorry. It was a stupid outburst. I… Let's just forget about it."
            
            $!{q_he} starts walking away, ${q_his} step a little less lighter than it was before. With a sigh, I start following ${q_him}.
            *goto ch5_met_someone
        #"Of course it's scary. I don't want to be left alone."
            A soft smile appears on his lips. "I'm not going to leave you alone. Alright?"
            
            "What does that mean? If you die, you will—"
            
            "You'll never be alone. I'll follow you as a ghost."
            
            "Again with the jokes!"
            
            "It's not a joke at all. I'm being super serious."
            
            Ugh!
            *goto ch5_quinn_goodbye
        #"I will save you."
            A little grin appears on ${q_his} face. "I know you will try."
            
            "Don't sound so defeated."
            
            "I'm not. I'm just… you didn't see what I saw." $!{q_he} shakes ${q_his} head. "Let's not talk about this anymore. Please."
            
            What did ${q_he} see? Is it about what happened during Samhain?
            *goto ch5_quinn_goodbye
        #Remain silent.
            I don't know what to say. What would the right words be for a moment like this? 
            
            $!{q_he} doesn't wait for me to say anything. $!{q_he} seldom does.
            *goto ch5_quinn_goodbye
*page_break
*label ch5_quinn_goodbye
$!{q_he} smiles and nods. "I hope you found out something useful about the fools you're forced to interact with."

*if not(quinn_dont_die)
    "I did."
    
    With a little chuckle, ${q_he} starts walking towards the town.
    
*if quinn_dont_die
    $!{q_he} touches my cheek with a little grin. "Don't worry about anything. I'm still here with you. Focus on that. Alright?"
    
    *fake_choice
        #Take ${q_his} hand before ${q_he} can retreat it.
            I take ${q_his} hand and keep it on my cheek. I refuse to let go of ${q_his} hand.
            
            $!{q_his} hand is so cold. $!{q_he} said that ${q_he}'s dying. Is that the reason for ${q_his} cold hands?
            
            The expression on ${q_his} face doesn't change, ${q_he} just tilts ${q_his} head slightly.
            
            "I love you," ${q_he} says again.
            
            I just want to make ${q_his} hands warm again.
            
            $!{q_he} lets go of me with a sad smile. "I'm sorry for my cold hands."
            
            $!{q_he} starts walking away in a slow pace, making sure I can follow ${q_him}.
        #"I love you."
            *if quinn_love_confusion
                My voice cracks a little at the end of the sentence.
            *if not(quinn_love_confusion)
                *set quinn_love true
                My voice cracks a little at the end of the sentence. I think it's the first time I've ever said it to anyone besides my family.
            $!{q_he} smiles when ${q_he} hears the words. $!{q_he} caresses my skin with ${q_his} freezing finger before looking at my lips.
            
            "I wish I could give you everything you ever wanted."
            
            "You—"
            
            $!{q_he} puts ${q_his} finger on my lips to stop me from talking. The suddenness of the movement makes my heart pound against my chest. $!{q_his} finger tip rests against my lips as if it belongs there, ${q_he}'s not in any hurry to move it away.
            
            "${name}," ${q_he} calls to my name and I focus my attention to ${q_him}, waiting for ${q_him} to speak. Then, ${q_he} grins. "You're as red as a cowberry."
            
            "Agh!" I swat ${q_his} hand away as ${q_he} starts laughing. "I'm serious!"
            
            "Me, too. You do look like one!"
            
            Ugh. There's no talking to ${q_him} when ${q_he}'s like that. With a scoff, I start walking.
            
            "Hey! Sorry! Don't walk so fast, come on!" $!{q_he} stumbles after me, laughter still lingering in ${q_his} voice.
            
            Stupid Quinn.
        #Nod. Alright.
            I will contact the Twins, I will make everything right.
            
            This is not the end. Mark my words.
            
            $!{q_he} smiles. "I love it when you're so serious."
            
            I frown.
            
            "Just like that!" $!{q_he} laughs and starts strutting away towards the town.
        #The though of losing ${q_him}... Tears sting in my eyes.
            I bite my lip and try to fight the tears back. I'm not going to cry. ${q_he}'s still here.
            
            "${name}," ${q_he} says with a pained expression. "You can always cry with me."
            
            Just when the words leave ${q_him}, the tears start running freely.
            
            $!{q_he} takes my face to ${q_his} hands. Then, with a tender look on ${q_his} face, ${q_he} kisses me on my cheek, intertwining my hand in ${q_his}. $!{q_he} catches a tear that falls on my cheek. 
            
            Then, another one. Another kiss of ${q_his} pillowy lips. Another tear caught in ${q_his} lips.
            
            Finally, there are no more tears to capture. Still, ${q_he} gives me one last kiss on my cheek, ${q_his} lips lingering against my skin, ${q_his} hot breath caressing me.
            
            "Your tears taste good," ${q_he} whispers.
            
            "That's a weird thing to say."
            
            "Sorry. They do, though. Salty."
            
            "That's great, I guess." My heart flutters, even if my words sound dry.
            
            With a little chuckle, ${q_he} retreats from me. "Come. It's getting cold."

*set ch5_met_someone true
*page_break
*goto ch5_met_someone
    